| 1 | AC_INIT(daemon/main.c) |
| 2 | AM_INIT_AUTOMAKE([doldaconnect], [0.5]) |
| 3 | AM_CONFIG_HEADER(config.h) |
| 4 | |
| 5 | DOLDA_AC_GROUP([Checking build chain]) |
| 6 | |
| 7 | AC_PROG_CC |
| 8 | AC_PROG_CC_C_O |
| 9 | AM_PROG_CC_C_O |
| 10 | AC_PROG_INSTALL |
| 11 | |
| 12 | DOLDA_AC_GROUP([Configuring gettext]) |
| 13 | |
| 14 | AM_GNU_GETTEXT_VERSION(0.12.1) |
| 15 | AM_GNU_GETTEXT([external]) |
| 16 | |
| 17 | DOLDA_AC_GROUP([Configuring libtool]) |
| 18 | |
| 19 | # Temporary hack to make libtool not check for g++ or g77 |
| 20 | m4_defun([_LT_AC_LANG_CXX_CONFIG], true) |
| 21 | m4_defun([_LT_AC_LANG_F77_CONFIG], true) |
| 22 | AC_PROG_LIBTOOL |
| 23 | |
| 24 | DOLDA_AC_GROUP([Checking required libraries]) |
| 25 | |
| 26 | AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib])) |
| 27 | AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib])) |
| 28 | AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm])) |
| 29 | |
| 30 | extlibs= |
| 31 | experimental=no |
| 32 | |
| 33 | DOLDA_AC_GROUP([Checking optional libraries]) |
| 34 | |
| 35 | # PAM check |
| 36 | pam_msg=no |
| 37 | AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication]) |
| 38 | AC_ARG_WITH(pam, [ --with-pam Enable PAM support]) |
| 39 | DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no], |
| 40 | [AC_CHECK_LIB(pam, pam_start, , [HAS_PAM=no])]) |
| 41 | if test "$with_pam" = yes -a "$HAS_PAM" = no; then |
| 42 | AC_MSG_ERROR([*** cannot find PAM on this system]) |
| 43 | fi |
| 44 | if test "$HAS_PAM" = yes; then |
| 45 | AC_DEFINE(HAVE_PAM) |
| 46 | pam_msg=yes |
| 47 | fi |
| 48 | |
| 49 | # Gtk 2.0 check |
| 50 | AC_ARG_WITH(gtk2, [ --with-gtk2 Enable GTK2 support]) |
| 51 | DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no], |
| 52 | [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])], |
| 53 | [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)], |
| 54 | [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)]) |
| 55 | if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then |
| 56 | AC_MSG_ERROR([*** cannot find GTK2 on this system]) |
| 57 | fi |
| 58 | |
| 59 | # libxml2 check |
| 60 | AC_ARG_WITH(libxml2, [ --with-libxml2 Enable libxml2 support]) |
| 61 | DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no], |
| 62 | [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])], |
| 63 | [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)], |
| 64 | [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)]) |
| 65 | if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then |
| 66 | AC_MSG_ERROR([*** cannot find libxml2 on this system]) |
| 67 | fi |
| 68 | |
| 69 | # libnotify check |
| 70 | AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify]) |
| 71 | AC_ARG_WITH(libnotify, [ --with-libnotify Enable libnotify support]) |
| 72 | DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no], |
| 73 | [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])], |
| 74 | [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)]) |
| 75 | if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then |
| 76 | AC_MSG_ERROR([*** cannot find libnotify on this system]) |
| 77 | fi |
| 78 | if test "$HAS_LIBNOTIFY" = yes; then |
| 79 | AC_DEFINE(HAVE_NOTIFY) |
| 80 | fi |
| 81 | |
| 82 | # libpanelapplet check |
| 83 | DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])]) |
| 84 | |
| 85 | # Gaim/Pidgin check |
| 86 | DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])], |
| 87 | [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)]) |
| 88 | DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])], |
| 89 | [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)]) |
| 90 | |
| 91 | # Gtk GUI check |
| 92 | DOLDA_ENABLE(gtk2ui, [ --enable-gtk2ui Enable the GTK2 user interface], yes, |
| 93 | [HAS_GTK2 HAS_LIBXML]) |
| 94 | AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes) |
| 95 | |
| 96 | # Dolconf check |
| 97 | DOLDA_ENABLE(dolconf, [ --enable-dolconf Build the configuration helper], yes, |
| 98 | [HAS_GTK2]) |
| 99 | AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes) |
| 100 | |
| 101 | # GUI shell check |
| 102 | DOLDA_ENABLE(guishell, [ --enable-guishell Build the GUI shell programs], yes, |
| 103 | [HAS_GTK2]) |
| 104 | AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes) |
| 105 | |
| 106 | # Gtk progress bar check |
| 107 | AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)]) |
| 108 | DOLDA_ENABLE(gtk2pbar, [ --enable-gtk2pbar Enable GTK2 progress bars (experimental)], no, |
| 109 | [HAS_GTK2 enable_gtk2ui]) |
| 110 | if test "$enable_gtk2pbar" = yes; then |
| 111 | experimental=yes |
| 112 | AC_DEFINE(ENABLE_GTK2PBAR) |
| 113 | fi |
| 114 | |
| 115 | # Gnome applet check |
| 116 | DOLDA_ENABLE(gnomeapplet, [ --enable-gnomeapplet Enable GNOME transfer applet (experimental)], no, |
| 117 | [HAS_LIBPANELAPPLET]) |
| 118 | if test "$enable_gnomeapplet" = yes; then |
| 119 | experimental=yes |
| 120 | fi |
| 121 | AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes) |
| 122 | |
| 123 | # Gaim plugin check |
| 124 | gaimplugin_msg= |
| 125 | DOLDA_ENABLE(gaimplugin, [ --enable-gaimplugin Enable Gaim chat plugin (experimental)], no, |
| 126 | [HAS_LIBGAIM]) |
| 127 | if test "$enable_gaimplugin" = yes; then |
| 128 | experimental=yes |
| 129 | gaimplugin_msg="Gaim $gaimplugin_msg" |
| 130 | fi |
| 131 | AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes) |
| 132 | DOLDA_ENABLE(pidginplugin, [ --enable-pidginplugin Enable Pidgin chat plugin (experimental)], no, |
| 133 | [HAS_LIBPURPLE]) |
| 134 | if test "$enable_pidginplugin" = yes; then |
| 135 | experimental=yes |
| 136 | gaimplugin_msg="Pidgin $gaimplugin_msg" |
| 137 | fi |
| 138 | AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes) |
| 139 | if test -z "$gaimplugin_msg"; then |
| 140 | gaimplugin_msg=none |
| 141 | fi |
| 142 | |
| 143 | # Guile check (XXX: Shouldn't have to be enabled manually) |
| 144 | guile_msg=no |
| 145 | if test "$with_guile" = yes; then |
| 146 | GUILE_FLAGS |
| 147 | extlibs="$extlibs guile" |
| 148 | guile_msg=yes |
| 149 | fi |
| 150 | |
| 151 | # Check whether to install baseconv |
| 152 | AC_ARG_ENABLE(baseconv, [ --enable-baseconv Install the baseconv utility]) |
| 153 | AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes) |
| 154 | |
| 155 | # Kerberos check |
| 156 | krb_msg=no |
| 157 | AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication]) |
| 158 | AC_ARG_WITH(krb5, [ --with-krb5[=PATH] Enable Kerberos 5 (not GSSAPI) authentication]) |
| 159 | AC_CHECK_PROG(KRBCONF, krb5-config, yes, no) |
| 160 | DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])], |
| 161 | [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])], |
| 162 | [HAS_COMERR=no]) |
| 163 | DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no], |
| 164 | [test "$KRBCONF" != yes && HAS_KRB5=no], |
| 165 | [test "$HAS_COMERR" = no && HAS_KRB5=no], |
| 166 | [KRB5_LIBS="`krb5-config --libs krb5`" |
| 167 | KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"] |
| 168 | [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)], |
| 169 | [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)]) |
| 170 | if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then |
| 171 | AC_MSG_ERROR([*** cannot find Kerberos 5 on this system]) |
| 172 | fi |
| 173 | if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then |
| 174 | AC_DEFINE(HAVE_KRB5) |
| 175 | krb_msg=yes |
| 176 | fi |
| 177 | AC_SUBST([KRB5_LIBS KRB5_CFLAGS]) |
| 178 | |
| 179 | DOLDA_AC_GROUP([Checking operating system features]) |
| 180 | |
| 181 | # Misc. functions checks |
| 182 | AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf])) |
| 183 | AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp]) |
| 184 | AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ]) |
| 185 | |
| 186 | AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system]) |
| 187 | AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ]) |
| 188 | |
| 189 | AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it]) |
| 190 | AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>]) |
| 191 | |
| 192 | AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs]) |
| 193 | AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER) |
| 194 | LDFLAGS="$LDFLAGS -lresolv" ]) |
| 195 | AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions]) |
| 196 | AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS) |
| 197 | LDFLAGS="$LDFLAGS -lkeyutils" ]) |
| 198 | |
| 199 | # Unix credentials selector |
| 200 | AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style]) |
| 201 | AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>]) |
| 202 | AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ]) |
| 203 | AC_MSG_CHECKING([for Unix auth style]) |
| 204 | if test $linuxcreds = y; then |
| 205 | AC_DEFINE(UNIX_AUTH_STYLE, 1) |
| 206 | AC_MSG_RESULT(linux) |
| 207 | elif test $bsdcreds = y; then |
| 208 | AC_DEFINE(UNIX_AUTH_STYLE, 2) |
| 209 | AC_MSG_RESULT(bsd) |
| 210 | else |
| 211 | AC_MSG_RESULT(none) |
| 212 | fi |
| 213 | |
| 214 | DOLDA_AC_GROUP([Checking standard headers]) |
| 215 | |
| 216 | AC_HEADER_STDC |
| 217 | AC_HEADER_DIRENT |
| 218 | AC_HEADER_SYS_WAIT |
| 219 | |
| 220 | AC_TYPE_PID_T |
| 221 | AC_TYPE_SIZE_T |
| 222 | AC_HEADER_TIME |
| 223 | AC_TYPE_SIGNAL |
| 224 | |
| 225 | CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS" |
| 226 | |
| 227 | DOLDA_AC_GROUP([Writing output]) |
| 228 | |
| 229 | AC_SUBST([extlibs]) |
| 230 | AC_OUTPUT([ |
| 231 | Makefile |
| 232 | autopackage/Makefile |
| 233 | common/Makefile |
| 234 | daemon/Makefile |
| 235 | lib/Makefile |
| 236 | lib/guile/Makefile |
| 237 | lib/guile/dolcon/Makefile |
| 238 | clients/Makefile |
| 239 | clients/gtk2/Makefile |
| 240 | clients/tty/Makefile |
| 241 | clients/gnome-trans-applet/Makefile |
| 242 | clients/gaim/Makefile |
| 243 | clients/gui-shell/Makefile |
| 244 | include/Makefile |
| 245 | include/doldaconnect/Makefile |
| 246 | doc/Makefile |
| 247 | doc/man/Makefile |
| 248 | po/Makefile.in |
| 249 | config/Makefile |
| 250 | config/cmd/Makefile |
| 251 | config/util/Makefile |
| 252 | contrib/Makefile |
| 253 | autopackage/dolcon.apspec |
| 254 | autopackage/dcuilib.apspec |
| 255 | autopackage/dcguile.apspec |
| 256 | ]) |
| 257 | |
| 258 | echo |
| 259 | echo "Dolda Connect has been configured with the following settings:" |
| 260 | echo |
| 261 | echo " PAM support: $pam_msg" |
| 262 | echo " Kerberos 5 support: $krb_msg" |
| 263 | echo " GTK2 user interface: $enable_gtk2ui" |
| 264 | echo " GTK2 progress bars: $enable_gtk2pbar" |
| 265 | echo " Dolconf configurator: $enable_dolconf" |
| 266 | echo " GUI shell: $enable_guishell" |
| 267 | echo " Guile extension library: $guile_msg" |
| 268 | echo " GNOME transfer applet: $enable_gnomeapplet" |
| 269 | echo " Gaim chat plugin: $gaimplugin_msg" |
| 270 | echo |
| 271 | |
| 272 | if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then |
| 273 | hastput=y |
| 274 | fi |
| 275 | if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then |
| 276 | if test "$hastput" = y; then |
| 277 | tput bold |
| 278 | tput setf 4 2>/dev/null |
| 279 | fi |
| 280 | echo -n " Warning: " >&2 |
| 281 | if test "$hastput" = y; then |
| 282 | tput sgr0 |
| 283 | fi |
| 284 | echo "Could not find a GTK2 development installation on this system." >&2 |
| 285 | echo " That means you won't get a UI." >&2 |
| 286 | echo " Make absolutely sure this is what you want!" >&2 |
| 287 | if test "$hastput" = y; then |
| 288 | tput bel |
| 289 | fi |
| 290 | sleep 1 |
| 291 | fi |
| 292 | if test "$experimental" = yes; then |
| 293 | if test "$hastput" = y; then |
| 294 | tput bold |
| 295 | tput setf 4 2>/dev/null |
| 296 | fi |
| 297 | echo -n " Warning: " >&2 |
| 298 | if test "$hastput" = y; then |
| 299 | tput sgr0 |
| 300 | fi |
| 301 | echo "You have enabled one or more experimental features!" >&2 |
| 302 | echo " Please don't complain that it doesn't work, unless" >&2 |
| 303 | echo " you have something constructive to add about the situation." >&2 |
| 304 | if test "$hastput" = y; then |
| 305 | tput bel |
| 306 | fi |
| 307 | sleep 1 |
| 308 | fi |