configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [1.4])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 experimental=no
  25
  26 DOLDA_AC_GROUP([Checking optional libraries])
  27
  28 # Standard libraries
  29 AC_CHECK_LIB(z, deflate, [HAS_LIBZ=yes], [HAS_LIBZ=no])
  30 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, [HAS_LIBBZ2=yes], [HAS_LIBBZ2=no])
  31 AC_CHECK_LIB(gdbm, gdbm_open, [HAS_GDBM=yes], [HAS_GDBM=no])
  32
  33 # PAM check
  34 pam_msg=no
  35 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  36 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  37 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  38                      [AC_CHECK_LIB(pam, pam_start, [:], [HAS_PAM=no])],
  39                      [PAM_LIBS=-lpam])
  40 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  41         AC_MSG_ERROR([*** cannot find PAM on this system])
  42 fi
  43 if test "$HAS_PAM" = yes; then
  44         AC_DEFINE(HAVE_PAM)
  45         pam_msg=yes
  46 fi
  47 AC_SUBST(PAM_LIBS)
  48
  49 # Gtk 2.0 check
  50 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  51 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  52                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  53                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  54                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  55 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  57 fi
  58 DOLDA_PKG([HAS_GTK2SI], [test "$HAS_GTK2" = no && HAS_GTK2SI=no],
  59                         [DOLDA_CHECK_FUNC(gtk_status_icon_new_from_pixbuf, [], [HAS_GTK2SI=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  60 DOLDA_PKG([HAS_GTK2ASS], [test "$HAS_GTK2" = no && HAS_GTK2ASS=no],
  61                          [DOLDA_CHECK_FUNC(gtk_assistant_new, [], [HAS_GTK2ASS=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  62
  63 # libxml2 check
  64 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  65 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  66                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  67                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  68                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  69 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  70         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  71 fi
  72
  73 # libnotify check
  74 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  75 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  76 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  77                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  78                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  79 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  80         AC_MSG_ERROR([*** cannot find libnotify on this system])
  81 fi
  82 if test "$HAS_LIBNOTIFY" = yes; then
  83         AC_DEFINE(HAVE_NOTIFY)
  84 fi
  85
  86 # libattr check
  87 AH_TEMPLATE(HAVE_XATTR, [define to compile support for extended attributes])
  88 AC_ARG_WITH(xattr, [  --with-xattr            Enable XATTR support])
  89 DOLDA_PKG([HAS_XATTR], [test "$with_xattr" = no && HAS_XATTR=no],
  90                        [AC_CHECK_LIB(attr, getxattr, [:], [HAS_XATTR=no])],
  91                        [DOLDA_CHECK_HEADER(attr/xattr.h, [], [HAS_XATTR=no])],
  92                        [XATTR_LIBS=-lattr])
  93 if test "$with_xattr" = yes -a "$HAS_XATTR" = no; then
  94         AC_MSG_ERROR([*** cannot find xattr support on this system])
  95 fi
  96 if test "$HAS_XATTR" = yes; then
  97         AC_DEFINE(HAVE_XATTR)
  98 fi
  99 AC_SUBST(XATTR_LIBS)
 100
 101 # libpanelapplet check
 102 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
 103
 104 # Gaim/Pidgin check
 105 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
 106                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
 107 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
 108                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
 109
 110 # Daemon check
 111 DOLDA_ENABLE(daemon, [  --enable-daemon         Enable the daemon], yes,
 112                      [HAS_LIBZ HAS_LIBBZ2 HAS_GDBM])
 113 AM_CONDITIONAL(DAEMON, test "$enable_daemon" = yes)
 114
 115 # ADC check
 116 DOLDA_ENABLE(fnetadc, [  --enable-fnetadc        Enable ADC code (experimental)], no,
 117                   [enable_daemon])
 118 if test "$enable_fnetadc" = yes; then
 119         experimental=yes
 120 fi
 121 AM_CONDITIONAL(ADC, test "$enable_fnetadc" = yes)
 122
 123 # Gtk GUI check
 124 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
 125                      [HAS_GTK2 HAS_LIBBZ2 HAS_LIBXML])
 126 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
 127
 128 # Dolconf check
 129 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
 130                       [HAS_GTK2], [HAS_GTK2ASS])
 131 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 132
 133 # GUI shell check
 134 DOLDA_ENABLE(guishell, [  --enable-guishell       Build the GUI shell programs], yes,
 135                        [HAS_GTK2], [HAS_GTK2SI])
 136 AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes)
 137
 138 # Gnome applet check
 139 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet], no,
 140                           [HAS_LIBPANELAPPLET])
 141 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 142
 143 # Gaim plugin check
 144 gaimplugin_msg=
 145 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin], no,
 146                          [HAS_LIBGAIM])
 147 if test "$enable_gaimplugin" = yes; then
 148         gaimplugin_msg="Gaim $gaimplugin_msg"
 149 fi
 150 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 151 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin], no,
 152                            [HAS_LIBPURPLE])
 153 if test "$enable_pidginplugin" = yes; then
 154         gaimplugin_msg="Pidgin $gaimplugin_msg"
 155 fi
 156 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 157 if test -z "$gaimplugin_msg"; then
 158         gaimplugin_msg=none
 159 fi
 160
 161 # Guile check (XXX: Shouldn't have to be enabled manually)
 162 enable_guile=no
 163 if test "$with_guile" = yes; then
 164         GUILE_FLAGS
 165         enable_guile=yes
 166 fi
 167 AM_CONDITIONAL(ELIB_GUILE, test "$enable_guile" = yes)
 168
 169 # Check whether to install baseconv
 170 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 171 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 172
 173 # Kerberos check
 174 krb_msg=no
 175 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 176 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 177 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 178 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 179                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 180                         [HAS_COMERR=no])
 181 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 182                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 183                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 184                       [KRB5_LIBS="`krb5-config --libs krb5`"
 185                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 186                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 187                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 188 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 189         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 190 fi
 191 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 192         AC_DEFINE(HAVE_KRB5)
 193         krb_msg=yes
 194 fi
 195 AC_SUBST(KRB5_LIBS)
 196 AC_SUBST(KRB_CFLAGS)
 197
 198 # Linux keyring
 199 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 200 AC_ARG_WITH(keyutils, [  --with-keyutils           Enable support for the Linux keyring stash])
 201 DOLDA_PKG([HAS_KEYUTILS], [test "$with_keyutils" = no && HAS_KEYUTILS=no],
 202                           [AC_CHECK_LIB(keyutils, keyctl_search, [:], [HAS_KEYUTILS=no])])
 203 if test "$with_keyutils" = yes -a "$HAS_KEYUTILS" = no; then
 204         AC_MSG_ERROR([*** cannot find keyutils on this system])
 205 fi
 206 if test "$HAS_KEYUTILS" = yes; then
 207         AC_DEFINE(HAVE_KEYUTILS)
 208         KEYUTILS_LIBS=-lkeyutils
 209 fi
 210 AC_SUBST([KEYUTILS_LIBS])
 211
 212 DOLDA_AC_GROUP([Checking operating system features])
 213
 214 # Misc. functions checks
 215 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 216 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 217 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 218
 219 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 220 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 221
 222 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 223 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 224
 225 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 226 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 227                                   LDFLAGS="$LDFLAGS -lresolv" ])
 228 AC_CHECK_LIB(resolv, __res_query, [ AC_DEFINE(HAVE_RESOLVER)
 229                                     LDFLAGS="$LDFLAGS -lresolv" ])
 230
 231 # Unix credentials selector
 232 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 233 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 234 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 235 AC_MSG_CHECKING([for Unix auth style])
 236 if test $linuxcreds = y; then
 237         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 238         AC_MSG_RESULT(linux)
 239 elif test $bsdcreds = y; then
 240         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 241         AC_MSG_RESULT(bsd)
 242 else
 243         AC_MSG_RESULT(none)
 244 fi
 245
 246 DOLDA_AC_GROUP([Checking standard headers])
 247
 248 AC_HEADER_STDC
 249 AC_HEADER_DIRENT
 250 AC_HEADER_SYS_WAIT
 251
 252 AC_TYPE_PID_T
 253 AC_TYPE_SIZE_T
 254 AC_HEADER_TIME
 255 AC_TYPE_SIGNAL
 256
 257 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 258
 259 DOLDA_AC_GROUP([Writing output])
 260
 261 AH_TEMPLATE(RELEASEINFO, [define release information reported by various programs (should be left to configure to define)])
 262 relinfo="relver ${VERSION}\\n"
 263 relinfo="${relinfo}builddate $(date)\\n"
 264 if test -d .git && which git-rev-parse >/dev/null 2>&1; then
 265         relinfo="${relinfo}source git $(git-rev-parse HEAD)\\n"
 266 elif test -r source; then
 267         relinfo="${relinfo}source $(cat source)\\n"
 268 else
 269         relinfo="${relinfo}source unknown\\n"
 270 fi
 271 AC_DEFINE_UNQUOTED([RELEASEINFO], ["$relinfo"])
 272
 273 AC_OUTPUT([
 274 Makefile
 275 autopackage/Makefile
 276 common/Makefile
 277 daemon/Makefile
 278 lib/Makefile
 279 lib/guile/Makefile
 280 lib/guile/dolcon/Makefile
 281 clients/Makefile
 282 clients/gtk2/Makefile
 283 clients/tty/Makefile
 284 clients/gnome-trans-applet/Makefile
 285 clients/gaim/Makefile
 286 clients/gui-shell/Makefile
 287 include/Makefile
 288 include/doldaconnect/Makefile
 289 doc/Makefile
 290 doc/man/Makefile
 291 po/Makefile.in
 292 config/Makefile
 293 config/cmd/Makefile
 294 config/util/Makefile
 295 contrib/Makefile
 296 contrib/doldaconnect.spec
 297 share/Makefile
 298 autopackage/doldacond.apspec
 299 autopackage/dolcon.apspec
 300 autopackage/dcuilib.apspec
 301 autopackage/dcguile.apspec
 302 autopackage/guishell.apspec
 303 ])
 304
 305 echo
 306 echo "Dolda Connect has been configured with the following settings:"
 307 echo
 308 echo "    Daemon:                     $enable_daemon"
 309 echo "    PAM support:                $pam_msg"
 310 echo "    Kerberos 5 support:         $krb_msg"
 311 echo "    ADC support (unfinished):   $enable_fnetadc"
 312 echo "    GTK2 user interface:        $enable_gtk2ui"
 313 echo "    Dolconf configurator:       $enable_dolconf"
 314 echo "    GUI shell:                  $enable_guishell"
 315 echo "    Guile extension library:    $enable_guile"
 316 echo "    GNOME transfer applet:      $enable_gnomeapplet"
 317 echo "    Gaim chat plugin:           $gaimplugin_msg"
 318 echo
 319
 320 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 321         hastput=y
 322 fi
 323 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 324         if test "$hastput" = y; then
 325                 tput bold
 326                 tput setf 4 2>/dev/null
 327         fi
 328         echo -n "    Warning: " >&2
 329         if test "$hastput" = y; then
 330                 tput sgr0
 331         fi
 332         echo "Could not find a GTK2 development installation on this system." >&2
 333         echo "             That means you won't get a UI." >&2
 334         echo "             Make absolutely sure this is what you want!" >&2
 335         if test "$hastput" = y; then
 336                 tput bel
 337         fi
 338         sleep 1
 339 fi
 340 if test "$experimental" = yes; then
 341         if test "$hastput" = y; then
 342                 tput bold
 343                 tput setf 4 2>/dev/null
 344         fi
 345         echo -n "    Warning: " >&2
 346         if test "$hastput" = y; then
 347                 tput sgr0
 348         fi
 349         echo "You have enabled one or more experimental features!" >&2
 350         echo "             Please don't complain that it doesn't work, unless" >&2
 351         echo "             you have something constructive to add about the situation." >&2
 352         if test "$hastput" = y; then
 353                 tput bel
 354         fi
 355         sleep 1
 356 fi