configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [1.3])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 experimental=no
  25
  26 DOLDA_AC_GROUP([Checking optional libraries])
  27
  28 # Standard libraries
  29 AC_CHECK_LIB(z, deflate, [HAS_LIBZ=yes], [HAS_LIBZ=no])
  30 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, [HAS_LIBBZ2=yes], [HAS_LIBBZ2=no])
  31 AC_CHECK_LIB(gdbm, gdbm_open, [HAS_GDBM=yes], [HAS_GDBM=no])
  32
  33 # PAM check
  34 pam_msg=no
  35 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  36 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  37 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  38                      [AC_CHECK_LIB(pam, pam_start, [:], [HAS_PAM=no])],
  39                      [PAM_LIBS=-lpam])
  40 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  41         AC_MSG_ERROR([*** cannot find PAM on this system])
  42 fi
  43 if test "$HAS_PAM" = yes; then
  44         AC_DEFINE(HAVE_PAM)
  45         pam_msg=yes
  46 fi
  47 AC_SUBST(PAM_LIBS)
  48
  49 # Gtk 2.0 check
  50 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  51 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  52                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  53                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  54                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  55 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  57 fi
  58 DOLDA_PKG([HAS_GTK2SI], [test "$HAS_GTK2" = no && HAS_GTK2SI=no],
  59                         [DOLDA_CHECK_FUNC(gtk_status_icon_new_from_pixbuf, [], [HAS_GTK2SI=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  60 DOLDA_PKG([HAS_GTK2ASS], [test "$HAS_GTK2" = no && HAS_GTK2ASS=no],
  61                          [DOLDA_CHECK_FUNC(gtk_assistant_new, [], [HAS_GTK2ASS=no], $GTK2_CFLAGS, $GTK2_LIBS)])
  62
  63 # libxml2 check
  64 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  65 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  66                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  67                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  68                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  69 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  70         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  71 fi
  72
  73 # libnotify check
  74 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  75 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  76 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  77                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  78                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  79 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  80         AC_MSG_ERROR([*** cannot find libnotify on this system])
  81 fi
  82 if test "$HAS_LIBNOTIFY" = yes; then
  83         AC_DEFINE(HAVE_NOTIFY)
  84 fi
  85
  86 # libattr check
  87 AH_TEMPLATE(HAVE_XATTR, [define to compile support for extended attributes])
  88 AC_ARG_WITH(xattr, [  --with-xattr            Enable XATTR support])
  89 DOLDA_PKG([HAS_XATTR], [test "$with_xattr" = no && HAS_XATTR=no],
  90                        [AC_CHECK_LIB(attr, getxattr, [:], [HAS_XATTR=no])],
  91                        [DOLDA_CHECK_HEADER(attr/xattr.h, [], [HAS_XATTR=no])],
  92                        [XATTR_LIBS=-lattr])
  93 if test "$with_xattr" = yes -a "$HAS_XATTR" = no; then
  94         AC_MSG_ERROR([*** cannot find xattr support on this system])
  95 fi
  96 if test "$HAS_XATTR" = yes; then
  97         AC_DEFINE(HAVE_XATTR)
  98 fi
  99 AC_SUBST(XATTR_LIBS)
 100
 101 # libpanelapplet check
 102 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
 103
 104 # Gaim/Pidgin check
 105 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
 106                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
 107 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
 108                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
 109
 110 # Daemon check
 111 DOLDA_ENABLE(daemon, [  --enable-daemon         Enable the daemon], yes,
 112                      [HAS_LIBZ HAS_LIBBZ2 HAS_GDBM])
 113 AM_CONDITIONAL(DAEMON, test "$enable_daemon" = yes)
 114
 115 # ADC check
 116 DOLDA_ENABLE(fnetadc, [  --enable-fnetadc        Enable ADC code (experimental)], no,
 117                   [enable_daemon])
 118 if test "$enable_fnetadc" = yes; then
 119         experimental=yes
 120 fi
 121 AM_CONDITIONAL(ADC, test "$enable_fnetadc" = yes)
 122
 123 # Gtk GUI check
 124 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
 125                      [HAS_GTK2 HAS_LIBBZ2 HAS_LIBXML])
 126 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
 127
 128 # Dolconf check
 129 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
 130                       [HAS_GTK2], [HAS_GTK2ASS])
 131 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 132
 133 # GUI shell check
 134 DOLDA_ENABLE(guishell, [  --enable-guishell       Build the GUI shell programs], yes,
 135                        [HAS_GTK2], [HAS_GTK2SI])
 136 AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes)
 137
 138 # Gnome applet check
 139 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet], no,
 140                           [HAS_LIBPANELAPPLET])
 141 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 142
 143 # Gaim plugin check
 144 gaimplugin_msg=
 145 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin], no,
 146                          [HAS_LIBGAIM])
 147 if test "$enable_gaimplugin" = yes; then
 148         gaimplugin_msg="Gaim $gaimplugin_msg"
 149 fi
 150 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 151 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin], no,
 152                            [HAS_LIBPURPLE])
 153 if test "$enable_pidginplugin" = yes; then
 154         gaimplugin_msg="Pidgin $gaimplugin_msg"
 155 fi
 156 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 157 if test -z "$gaimplugin_msg"; then
 158         gaimplugin_msg=none
 159 fi
 160
 161 # Guile check (XXX: Shouldn't have to be enabled manually)
 162 enable_guile=no
 163 if test "$with_guile" = yes; then
 164         GUILE_FLAGS
 165         enable_guile=yes
 166 fi
 167 AM_CONDITIONAL(ELIB_GUILE, test "$enable_guile" = yes)
 168
 169 # Check whether to install baseconv
 170 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 171 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 172
 173 # Kerberos check
 174 krb_msg=no
 175 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 176 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 177 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 178 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 179                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 180                         [HAS_COMERR=no])
 181 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 182                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 183                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 184                       [KRB5_LIBS="`krb5-config --libs krb5`"
 185                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 186                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 187                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 188 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 189         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 190 fi
 191 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 192         AC_DEFINE(HAVE_KRB5)
 193         krb_msg=yes
 194 fi
 195 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 196
 197 # Linux keyring
 198 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 199 AC_ARG_WITH(keyutils, [  --with-keyutils           Enable support for the Linux keyring stash])
 200 DOLDA_PKG([HAS_KEYUTILS], [test "$with_keyutils" = no && HAS_KEYUTILS=no],
 201                           [AC_CHECK_LIB(keyutils, keyctl_search, [:], [HAS_KEYUTILS=no])])
 202 if test "$with_keyutils" = yes -a "$HAS_KEYUTILS" = no; then
 203         AC_MSG_ERROR([*** cannot find keyutils on this system])
 204 fi
 205 if test "$HAS_KEYUTILS" = yes; then
 206         AC_DEFINE(HAVE_KEYUTILS)
 207         KEYUTILS_LIBS=-lkeyutils
 208 fi
 209 AC_SUBST([KEYUTILS_LIBS])
 210
 211 DOLDA_AC_GROUP([Checking operating system features])
 212
 213 # Misc. functions checks
 214 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 215 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 216 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 217
 218 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 219 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 220
 221 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 222 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 223
 224 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 225 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 226                                   LDFLAGS="$LDFLAGS -lresolv" ])
 227 AC_CHECK_LIB(resolv, __res_query, [ AC_DEFINE(HAVE_RESOLVER)
 228                                     LDFLAGS="$LDFLAGS -lresolv" ])
 229
 230 # Unix credentials selector
 231 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 232 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 233 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 234 AC_MSG_CHECKING([for Unix auth style])
 235 if test $linuxcreds = y; then
 236         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 237         AC_MSG_RESULT(linux)
 238 elif test $bsdcreds = y; then
 239         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 240         AC_MSG_RESULT(bsd)
 241 else
 242         AC_MSG_RESULT(none)
 243 fi
 244
 245 DOLDA_AC_GROUP([Checking standard headers])
 246
 247 AC_HEADER_STDC
 248 AC_HEADER_DIRENT
 249 AC_HEADER_SYS_WAIT
 250
 251 AC_TYPE_PID_T
 252 AC_TYPE_SIZE_T
 253 AC_HEADER_TIME
 254 AC_TYPE_SIGNAL
 255
 256 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 257
 258 DOLDA_AC_GROUP([Writing output])
 259
 260 AH_TEMPLATE(RELEASEINFO, [define release information reported by various programs (should be left to configure to define)])
 261 relinfo="relver ${VERSION}\\n"
 262 relinfo="${relinfo}builddate $(date)\\n"
 263 if test -d .git && which git-rev-parse >/dev/null 2>&1; then
 264         relinfo="${relinfo}source git $(git-rev-parse HEAD)\\n"
 265 elif test -r source; then
 266         relinfo="${relinfo}source $(cat source)\\n"
 267 else
 268         relinfo="${relinfo}source unknown\\n"
 269 fi
 270 AC_DEFINE_UNQUOTED([RELEASEINFO], ["$relinfo"])
 271
 272 AC_OUTPUT([
 273 Makefile
 274 autopackage/Makefile
 275 common/Makefile
 276 daemon/Makefile
 277 lib/Makefile
 278 lib/guile/Makefile
 279 lib/guile/dolcon/Makefile
 280 clients/Makefile
 281 clients/gtk2/Makefile
 282 clients/tty/Makefile
 283 clients/gnome-trans-applet/Makefile
 284 clients/gaim/Makefile
 285 clients/gui-shell/Makefile
 286 include/Makefile
 287 include/doldaconnect/Makefile
 288 doc/Makefile
 289 doc/man/Makefile
 290 po/Makefile.in
 291 config/Makefile
 292 config/cmd/Makefile
 293 config/util/Makefile
 294 contrib/Makefile
 295 contrib/doldaconnect.spec
 296 share/Makefile
 297 autopackage/doldacond.apspec
 298 autopackage/dolcon.apspec
 299 autopackage/dcuilib.apspec
 300 autopackage/dcguile.apspec
 301 autopackage/guishell.apspec
 302 ])
 303
 304 echo
 305 echo "Dolda Connect has been configured with the following settings:"
 306 echo
 307 echo "    Daemon:                     $enable_daemon"
 308 echo "    PAM support:                $pam_msg"
 309 echo "    Kerberos 5 support:         $krb_msg"
 310 echo "    ADC support (unfinished):   $enable_fnetadc"
 311 echo "    GTK2 user interface:        $enable_gtk2ui"
 312 echo "    Dolconf configurator:       $enable_dolconf"
 313 echo "    GUI shell:                  $enable_guishell"
 314 echo "    Guile extension library:    $enable_guile"
 315 echo "    GNOME transfer applet:      $enable_gnomeapplet"
 316 echo "    Gaim chat plugin:           $gaimplugin_msg"
 317 echo
 318
 319 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 320         hastput=y
 321 fi
 322 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 323         if test "$hastput" = y; then
 324                 tput bold
 325                 tput setf 4 2>/dev/null
 326         fi
 327         echo -n "    Warning: " >&2
 328         if test "$hastput" = y; then
 329                 tput sgr0
 330         fi
 331         echo "Could not find a GTK2 development installation on this system." >&2
 332         echo "             That means you won't get a UI." >&2
 333         echo "             Make absolutely sure this is what you want!" >&2
 334         if test "$hastput" = y; then
 335                 tput bel
 336         fi
 337         sleep 1
 338 fi
 339 if test "$experimental" = yes; then
 340         if test "$hastput" = y; then
 341                 tput bold
 342                 tput setf 4 2>/dev/null
 343         fi
 344         echo -n "    Warning: " >&2
 345         if test "$hastput" = y; then
 346                 tput sgr0
 347         fi
 348         echo "You have enabled one or more experimental features!" >&2
 349         echo "             Please don't complain that it doesn't work, unless" >&2
 350         echo "             you have something constructive to add about the situation." >&2
 351         if test "$hastput" = y; then
 352                 tput bel
 353         fi
 354         sleep 1
 355 fi