configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [1.1])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 DOLDA_AC_GROUP([Checking required libraries])
  25
  26 AC_CHECK_LIB(z, deflate, [:], AC_MSG_ERROR([*** must have zlib]))
  27 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, [:], AC_MSG_ERROR([*** must have bzlib]))
  28 AC_CHECK_LIB(gdbm, gdbm_open, [:], AC_MSG_ERROR([*** must have gdbm]))
  29
  30 experimental=no
  31
  32 DOLDA_AC_GROUP([Checking optional libraries])
  33
  34 # PAM check
  35 pam_msg=no
  36 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  37 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  38 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  39                      [AC_CHECK_LIB(pam, pam_start, [:], [HAS_PAM=no])],
  40                      [PAM_LIBS=-lpam])
  41 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  42         AC_MSG_ERROR([*** cannot find PAM on this system])
  43 fi
  44 if test "$HAS_PAM" = yes; then
  45         AC_DEFINE(HAVE_PAM)
  46         pam_msg=yes
  47 fi
  48 AC_SUBST(PAM_LIBS)
  49
  50 # Gtk 2.0 check
  51 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  52 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  53                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  54                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  55                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  56 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  57         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  58 fi
  59
  60 # libxml2 check
  61 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  62 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  63                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  64                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  65                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  66 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  67         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  68 fi
  69
  70 # libnotify check
  71 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  72 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  73 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  74                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  75                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  76 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  77         AC_MSG_ERROR([*** cannot find libnotify on this system])
  78 fi
  79 if test "$HAS_LIBNOTIFY" = yes; then
  80         AC_DEFINE(HAVE_NOTIFY)
  81 fi
  82
  83 # libpanelapplet check
  84 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  85
  86 # Gaim/Pidgin check
  87 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  88                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  89 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  90                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  91
  92 # Daemon check
  93 DOLDA_ENABLE(daemon, [  --enable-daemon         Enable the daemon], yes, [])
  94 AM_CONDITIONAL(DAEMON, test "$enable_daemon" = yes)
  95
  96 # Gtk GUI check
  97 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
  98                      [HAS_GTK2 HAS_LIBXML])
  99 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
 100
 101 # Dolconf check
 102 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
 103                       [HAS_GTK2])
 104 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 105
 106 # GUI shell check
 107 DOLDA_ENABLE(guishell, [  --enable-guishell       Build the GUI shell programs], yes,
 108                        [HAS_GTK2])
 109 AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes)
 110
 111 # Gnome applet check
 112 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
 113                           [HAS_LIBPANELAPPLET])
 114 if test "$enable_gnomeapplet" = yes; then
 115         experimental=yes
 116 fi
 117 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 118
 119 # Gaim plugin check
 120 gaimplugin_msg=
 121 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 122                          [HAS_LIBGAIM])
 123 if test "$enable_gaimplugin" = yes; then
 124         experimental=yes
 125         gaimplugin_msg="Gaim $gaimplugin_msg"
 126 fi
 127 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 128 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 129                            [HAS_LIBPURPLE])
 130 if test "$enable_pidginplugin" = yes; then
 131         experimental=yes
 132         gaimplugin_msg="Pidgin $gaimplugin_msg"
 133 fi
 134 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 135 if test -z "$gaimplugin_msg"; then
 136         gaimplugin_msg=none
 137 fi
 138
 139 # Guile check (XXX: Shouldn't have to be enabled manually)
 140 enable_guile=no
 141 if test "$with_guile" = yes; then
 142         GUILE_FLAGS
 143         enable_guile=yes
 144 fi
 145 AM_CONDITIONAL(ELIB_GUILE, test "$enable_guile" = yes)
 146
 147 # Check whether to install baseconv
 148 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 149 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 150
 151 # Kerberos check
 152 krb_msg=no
 153 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 154 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 155 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 156 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 157                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 158                         [HAS_COMERR=no])
 159 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 160                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 161                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 162                       [KRB5_LIBS="`krb5-config --libs krb5`"
 163                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 164                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 165                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 166 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 167         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 168 fi
 169 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 170         AC_DEFINE(HAVE_KRB5)
 171         krb_msg=yes
 172 fi
 173 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 174
 175 # Linux keyring
 176 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 177 AC_ARG_WITH(keyutils, [  --with-keyutils           Enable support for the Linux keyring stash])
 178 DOLDA_PKG([HAS_KEYUTILS], [test "$with_keyutils" = no && HAS_KEYUTILS=no],
 179                           [AC_CHECK_LIB(keyutils, keyctl_search, [:], [HAS_KEYUTILS=no])])
 180 if test "$with_keyutils" = yes -a "$HAS_KEYUTILS" = no; then
 181         AC_MSG_ERROR([*** cannot find keyutils on this system])
 182 fi
 183 if test "$HAS_KEYUTILS" = yes; then
 184         AC_DEFINE(HAVE_KEYUTILS)
 185         KEYUTILS_LIBS=-lkeyutils
 186 fi
 187 AC_SUBST([KEYUTILS_LIBS])
 188
 189 DOLDA_AC_GROUP([Checking operating system features])
 190
 191 # Misc. functions checks
 192 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 193 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 194 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 195
 196 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 197 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 198
 199 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 200 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 201
 202 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 203 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 204                                   LDFLAGS="$LDFLAGS -lresolv" ])
 205 AC_CHECK_LIB(resolv, __res_query, [ AC_DEFINE(HAVE_RESOLVER)
 206                                     LDFLAGS="$LDFLAGS -lresolv" ])
 207
 208 # Unix credentials selector
 209 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 210 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 211 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 212 AC_MSG_CHECKING([for Unix auth style])
 213 if test $linuxcreds = y; then
 214         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 215         AC_MSG_RESULT(linux)
 216 elif test $bsdcreds = y; then
 217         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 218         AC_MSG_RESULT(bsd)
 219 else
 220         AC_MSG_RESULT(none)
 221 fi
 222
 223 DOLDA_AC_GROUP([Checking standard headers])
 224
 225 AC_HEADER_STDC
 226 AC_HEADER_DIRENT
 227 AC_HEADER_SYS_WAIT
 228
 229 AC_TYPE_PID_T
 230 AC_TYPE_SIZE_T
 231 AC_HEADER_TIME
 232 AC_TYPE_SIGNAL
 233
 234 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 235
 236 DOLDA_AC_GROUP([Writing output])
 237
 238 AH_TEMPLATE(RELEASEINFO, [define release information reported by various programs (should be left to configure to define)])
 239 relinfo="relver ${VERSION}\\n"
 240 relinfo="${relinfo}builddate $(date)\\n"
 241 if test -d .git && which git-rev-parse >/dev/null 2>&1; then
 242         relinfo="${relinfo}source git $(git-rev-parse HEAD)\\n"
 243 elif test -r source; then
 244         relinfo="${relinfo}source $(cat source)\\n"
 245 else
 246         relinfo="${relinfo}source unknown\\n"
 247 fi
 248 AC_DEFINE_UNQUOTED([RELEASEINFO], ["$relinfo"])
 249
 250 AC_OUTPUT([
 251 Makefile
 252 autopackage/Makefile
 253 common/Makefile
 254 daemon/Makefile
 255 lib/Makefile
 256 lib/guile/Makefile
 257 lib/guile/dolcon/Makefile
 258 clients/Makefile
 259 clients/gtk2/Makefile
 260 clients/tty/Makefile
 261 clients/gnome-trans-applet/Makefile
 262 clients/gaim/Makefile
 263 clients/gui-shell/Makefile
 264 include/Makefile
 265 include/doldaconnect/Makefile
 266 doc/Makefile
 267 doc/man/Makefile
 268 po/Makefile.in
 269 config/Makefile
 270 config/cmd/Makefile
 271 config/util/Makefile
 272 contrib/Makefile
 273 contrib/doldaconnect.spec
 274 share/Makefile
 275 autopackage/doldacond.apspec
 276 autopackage/dolcon.apspec
 277 autopackage/dcuilib.apspec
 278 autopackage/dcguile.apspec
 279 autopackage/guishell.apspec
 280 ])
 281
 282 echo
 283 echo "Dolda Connect has been configured with the following settings:"
 284 echo
 285 echo "    Daemon:                  $enable_daemon"
 286 echo "    PAM support:             $pam_msg"
 287 echo "    Kerberos 5 support:      $krb_msg"
 288 echo "    GTK2 user interface:     $enable_gtk2ui"
 289 echo "    Dolconf configurator:    $enable_dolconf"
 290 echo "    GUI shell:               $enable_guishell"
 291 echo "    Guile extension library: $enable_guile"
 292 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 293 echo "    Gaim chat plugin:        $gaimplugin_msg"
 294 echo
 295
 296 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 297         hastput=y
 298 fi
 299 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 300         if test "$hastput" = y; then
 301                 tput bold
 302                 tput setf 4 2>/dev/null
 303         fi
 304         echo -n "    Warning: " >&2
 305         if test "$hastput" = y; then
 306                 tput sgr0
 307         fi
 308         echo "Could not find a GTK2 development installation on this system." >&2
 309         echo "             That means you won't get a UI." >&2
 310         echo "             Make absolutely sure this is what you want!" >&2
 311         if test "$hastput" = y; then
 312                 tput bel
 313         fi
 314         sleep 1
 315 fi
 316 if test "$experimental" = yes; then
 317         if test "$hastput" = y; then
 318                 tput bold
 319                 tput setf 4 2>/dev/null
 320         fi
 321         echo -n "    Warning: " >&2
 322         if test "$hastput" = y; then
 323                 tput sgr0
 324         fi
 325         echo "You have enabled one or more experimental features!" >&2
 326         echo "             Please don't complain that it doesn't work, unless" >&2
 327         echo "             you have something constructive to add about the situation." >&2
 328         if test "$hastput" = y; then
 329                 tput bel
 330         fi
 331         sleep 1
 332 fi