configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.3])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7
   8 AM_GNU_GETTEXT_VERSION(0.12.1)
   9 AM_GNU_GETTEXT([external])
  10 AM_PROG_LIBTOOL
  11
  12 AC_CHECK_LIB(pam, pam_start, , AC_MSG_ERROR([*** must have PAM]))
  13 AC_CHECK_LIB(dl, dlopen, , AC_MSG_ERROR([*** PAM requires a working dynamic loader (libdl)]))
  14 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
  15 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
  16 AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm]))
  17
  18 clients=
  19 extlibs=
  20 experimental=no
  21
  22 AC_CHECK_PROG([PKG_CONFIG], pkg-config, yes, no)
  23
  24 # Gtk 2.0 check
  25 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  26 if test "$with_gtk2" = no; then
  27         HAS_GTK2=no
  28 fi
  29 if test "$HAS_GTK2" != no; then
  30         if test "$PKG_CONFIG" = yes; then
  31                 AC_MSG_CHECKING([for GTK2 package information])
  32                 if pkg-config --modversion gtk+-2.0 >/dev/null 2>&1; then
  33                         AC_MSG_RESULT(yes)
  34                 else
  35                         AC_MSG_RESULT(no)
  36                         HAS_GTK2=no
  37                 fi
  38                 if test "$HAS_GTK2" != no; then
  39                         AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [HAS_GTK2=yes], [HAS_GTK2=no], `pkg-config --libs gtk+-2.0`)
  40                 fi
  41                 if test "$HAS_GTK2" = yes; then
  42                         cpp_bak="$CPPFLAGS"
  43                         CPPFLAGS="$CPPFLAGS `pkg-config --cflags gtk+-2.0`"
  44                         AC_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no])
  45                         CPPFLAGS="$cpp_bak"
  46                 fi
  47         else
  48                 HAS_GTK2=no
  49         fi
  50 fi
  51 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  52         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  53 fi
  54
  55 # libxml2 check
  56 AC_MSG_CHECKING([for libxml2 package information])
  57 if test "$PKG_CONFIG" = yes; then
  58         if pkg-config --modversion libxml-2.0 >/dev/null 2>&1; then
  59                 AC_MSG_RESULT(yes)
  60         else
  61                 AC_MSG_RESULT(no)
  62                 HAS_LIBXML=no
  63         fi
  64         if test "$HAS_LIBXML" != no; then
  65                 AC_CHECK_LIB(xml2, xmlReadFile, [HAS_LIBXML=yes], [HAS_LIBXML=no], `pkg-config --libs libxml-2.0`)
  66         fi
  67 else
  68         AC_MSG_RESULT(no)
  69         HAS_LIBXML=no
  70 fi
  71
  72 # Gtk GUI check
  73 gtk2ui_msg=No
  74 AC_ARG_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface])
  75 if test "$enable_gtk2ui" = yes; then
  76         if test "$HAS_GTK2" = no; then
  77                 AC_MSG_ERROR([*** cannot build the GTK2 UI without a GTK2 library])
  78         fi
  79         if test "$HAS_LIBXML" = no; then
  80                 AC_MSG_ERROR([*** the GTK2 UI needs libxml2])
  81         fi
  82 fi
  83 if test "$enable_gtk2ui" != no -a "$HAS_GTK2" = yes; then
  84         clients="$clients gtk2"
  85         gtk2ui_msg=Yes
  86 fi
  87
  88 # Gtk progress bar check
  89 gtk2pbar_msg=No
  90 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
  91 AC_ARG_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)])
  92 if test "$enable_gtk2pbar" = yes; then
  93         if test "$HAS_GTK2" = no; then
  94                 AC_MSG_ERROR([*** cannot build GTK2 progress bars without GTK2])
  95         fi
  96         experimental=yes
  97         gtk2pbar_msg=Yes
  98         AC_DEFINE(ENABLE_GTK2PBAR)
  99 fi
 100
 101 # Gnome applet check
 102 gnometrapplet_msg=No
 103 AC_ARG_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)])
 104 if test "$enable_gnomeapplet" = yes; then
 105         experimental=yes
 106         gnometrapplet_msg=Yes
 107         clients="$clients gnome-trans-applet"
 108 fi
 109
 110 # Gaim plugin check
 111 gaimplugin_msg=No
 112 AC_ARG_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable GNOME transfer applet (experimental)])
 113 if test "$enable_gaimplugin" = yes; then
 114         experimental=yes
 115         gaimplugin_msg=Yes
 116         clients="$clients gaim"
 117 fi
 118
 119 # Guile check (XXX: Shouldn't have to be enabled manually)
 120 guile_msg=No
 121 if test "$with_guile" = yes; then
 122         GUILE_FLAGS
 123         extlibs="$extlibs guile"
 124         guile_msg=Yes
 125 fi
 126
 127 # Kerberos check
 128 krb_msg=No
 129 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSS-API) authentication])
 130 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 131 if test "$with_krb5" != no; then
 132         cpp_bak="$CPPFLAGS"
 133         ld_bak="$LDFLAGS"
 134         if test "$with_krb5" != yes; then
 135                 CPPFLAGS="$CPPFLAGS -I${with_krb5}/include"
 136                 LDFLAGS="$LDFLAGS -L${with_krb5}/lib"
 137         fi
 138         AC_CHECK_LIB(krb5, krb5_init_context, [HAS_KRB5=yes], [HAS_KRB5=no])
 139         if test "$HAS_KRB5" = yes; then
 140                 AC_CHECK_HEADER(com_err.h, [HAS_COMERR=yes], [HAS_COMERR=no])
 141                 if test "$HAS_COMERR" = no; then
 142                         AC_CHECK_HEADER(et/com_err.h, [HAS_COMERR=yes; CPPFLAGS="$CPPFLAGS -I/usr/include/et"], [])
 143                 fi
 144         fi
 145         if test "$HAS_COMERR" = no; then
 146                 HAS_KRB5=no
 147         fi
 148         if test "$HAS_KRB5" = no; then
 149                 CPPFLAGS="$cpp_bak"
 150                 LDFLAGS="$ld_bak"
 151         fi
 152 fi
 153 KRB5_LDADD=
 154 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" != yes; then
 155         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system - try passing --with-krb5=/path/to/kerberos])
 156 fi
 157 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 158         AC_DEFINE(HAVE_KRB5)
 159         KRB5_LDADD=-lkrb5
 160         krb_msg=Yes
 161 fi
 162 AC_SUBST([KRB5_LDADD])
 163
 164 # Misc. functions checks
 165 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 166 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 167 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 168
 169 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 170 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 171
 172 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 173 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 174
 175 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 176 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 177                                   LDFLAGS="$LDFLAGS -lresolv" ])
 178 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 179 AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS)
 180                                         LDFLAGS="$LDFLAGS -lkeyutils" ])
 181
 182 AC_HEADER_STDC
 183 AC_HEADER_DIRENT
 184 AC_HEADER_SYS_WAIT
 185
 186 AC_TYPE_PID_T
 187 AC_TYPE_SIZE_T
 188 AC_HEADER_TIME
 189 AC_TYPE_SIGNAL
 190
 191 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 192
 193 AC_SUBST([clients extlibs])
 194 AC_OUTPUT([
 195 Makefile
 196 autopackage/Makefile
 197 daemon/Makefile
 198 lib/Makefile
 199 lib/guile/Makefile
 200 lib/guile/dolcon/Makefile
 201 clients/Makefile
 202 clients/gtk2/Makefile
 203 clients/gnome-trans-applet/Makefile
 204 clients/gaim/Makefile
 205 include/Makefile
 206 include/doldaconnect/Makefile
 207 po/Makefile.in
 208 config/Makefile
 209 autopackage/dolcon.apspec
 210 autopackage/dcuilib.apspec
 211 autopackage/dcguile.apspec
 212 ])
 213
 214 echo
 215 echo "Dolda Connect has been configured with the following settings:"
 216 echo
 217 echo "    Kerberos 5 support:      $krb_msg"
 218 echo "    GTK2 user interface:     $gtk2ui_msg"
 219 echo "    GTK2 progress bars:      $gtk2pbar_msg"
 220 echo "    Guile extension library: $guile_msg"
 221 echo "    GNOME transfer applet:   $gnometrapplet_msg"
 222 echo "    Gaim chat plugin:        $gaimplugin_msg"
 223 echo
 224
 225 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 226         hastput=y
 227 fi
 228 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 229         if test "$hastput" = y; then
 230                 tput bold
 231                 tput setf 4 2>/dev/null
 232         fi
 233         echo -n "    Warning: " >&2
 234         if test "$hastput" = y; then
 235                 tput sgr0
 236         fi
 237         echo "Could not find a GTK2 development installation on this system." >&2
 238         echo "             That means you won't get a UI." >&2
 239         echo "             Make absolutely sure this is what you want!" >&2
 240         if test "$hastput" = y; then
 241                 tput bel
 242         fi
 243         sleep 1
 244 fi
 245 if test "$experimental" = yes; then
 246         if test "$hastput" = y; then
 247                 tput bold
 248                 tput setf 4 2>/dev/null
 249         fi
 250         echo -n "    Warning: " >&2
 251         if test "$hastput" = y; then
 252                 tput sgr0
 253         fi
 254         echo "You have enabled one or more experimental features!" >&2
 255         echo "             Please don't complain that it doesn't work, unless" >&2
 256         echo "             you have something constructive to add about the situation." >&2
 257         if test "$hastput" = y; then
 258                 tput bel
 259         fi
 260         sleep 1
 261 fi