Use AC_PROG_LIBTOOL instead of AM_PROG_LIBTOOL.
[doldaconnect.git] / configure.in
1 AC_INIT(daemon/main.c)
2 AM_INIT_AUTOMAKE([doldaconnect], [0.4])
3 AM_CONFIG_HEADER(config.h)
4
5 AC_PROG_CC
6 AC_PROG_INSTALL
7
8 AM_GNU_GETTEXT_VERSION(0.12.1)
9 AM_GNU_GETTEXT([external])
10
11 # Temporary hack to make libtool not check for g++ or g77
12 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
13 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
14 AC_PROG_LIBTOOL
15
16 AC_CHECK_LIB(pam, pam_start, , AC_MSG_ERROR([*** must have PAM]))
17 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
18 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
19 AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm]))
20
21 clients=tty
22 extlibs=
23 experimental=no
24
25 AC_CHECK_PROG([PKG_CONFIG], pkg-config, yes, no)
26
27 # Gtk 2.0 check
28 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
29 if test "$with_gtk2" = no; then
30         HAS_GTK2=no
31 fi
32 if test "$HAS_GTK2" != no; then
33         if test "$PKG_CONFIG" = yes; then
34                 AC_MSG_CHECKING([for GTK2 package information])
35                 if pkg-config --modversion gtk+-2.0 >/dev/null 2>&1; then
36                         AC_MSG_RESULT(yes)
37                 else
38                         AC_MSG_RESULT(no)
39                         HAS_GTK2=no
40                 fi
41                 if test "$HAS_GTK2" != no; then
42                         AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [HAS_GTK2=yes], [HAS_GTK2=no], `pkg-config --libs gtk+-2.0`)
43                 fi
44                 if test "$HAS_GTK2" = yes; then
45                         cpp_bak="$CPPFLAGS"
46                         CPPFLAGS="$CPPFLAGS `pkg-config --cflags gtk+-2.0`"
47                         AC_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no])
48                         CPPFLAGS="$cpp_bak"
49                 fi
50         else
51                 HAS_GTK2=no
52         fi
53 fi
54 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
55         AC_MSG_ERROR([*** cannot find GTK2 on this system])
56 fi
57
58 # libxml2 check
59 AC_MSG_CHECKING([for libxml2 package information])
60 if test "$PKG_CONFIG" = yes; then
61         if pkg-config --modversion libxml-2.0 >/dev/null 2>&1; then
62                 AC_MSG_RESULT(yes)
63         else
64                 AC_MSG_RESULT(no)
65                 HAS_LIBXML=no
66         fi
67         if test "$HAS_LIBXML" != no; then
68                 AC_CHECK_LIB(xml2, xmlReadFile, [HAS_LIBXML=yes], [HAS_LIBXML=no], `pkg-config --libs libxml-2.0`)
69         fi
70 else
71         AC_MSG_RESULT(no)
72         HAS_LIBXML=no
73 fi
74
75 # libnotify check
76 AC_MSG_CHECKING([for libnotify package information])
77 if test "$PKG_CONFIG" = yes; then
78         if pkg-config --modversion libnotify >/dev/null 2>&1; then
79                 AC_MSG_RESULT(yes)
80         else
81                 AC_MSG_RESULT(no)
82                 HAS_LIBNOTIFY=no
83         fi
84 else
85         AC_MSG_RESULT(no)
86         HAS_LIBNOTIFY=no
87 fi
88 if test "$HAS_LIBNOTIFY" != no; then
89         AC_CHECK_LIB(notify, notify_init, [HAS_LIBNOTIFY=yes], [HAS_LIBNOTIFY=no], `pkg-config --libs libnotify`)
90 fi
91
92 # Gtk GUI check
93 gtk2ui_msg=No
94 AC_ARG_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface])
95 if test "$enable_gtk2ui" = yes; then
96         if test "$HAS_GTK2" = no; then
97                 AC_MSG_ERROR([*** cannot build the GTK2 UI without a GTK2 library])
98         fi
99         if test "$HAS_LIBXML" = no; then
100                 AC_MSG_ERROR([*** the GTK2 UI needs libxml2])
101         fi
102 fi
103 if test "$enable_gtk2ui" != no -a "$HAS_GTK2" = yes; then
104         clients="$clients gtk2"
105         gtk2ui_msg=Yes
106 fi
107
108 # Dolconf check
109 dolconf_msg=No
110 AC_ARG_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper])
111 if test "$enable_dolconf" = yes -a "$HAS_GTK2" = no; then
112         AC_MSG_ERROR([*** cannot build dolconf without GTK2])
113 fi
114 if test "$enable_dolconf" != no -a "$HAS_GTK2" = yes; then
115         AM_CONDITIONAL(DOLCONF, true)
116         dolconf_msg=Yes
117 else
118         AM_CONDITIONAL(DOLCONF, false)
119 fi
120
121 # Gtk progress bar check
122 gtk2pbar_msg=No
123 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
124 AC_ARG_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)])
125 if test "$enable_gtk2pbar" = yes; then
126         if test "$HAS_GTK2" = no; then
127                 AC_MSG_ERROR([*** cannot build GTK2 progress bars without GTK2])
128         fi
129         experimental=yes
130         gtk2pbar_msg=Yes
131         AC_DEFINE(ENABLE_GTK2PBAR)
132 fi
133
134 # Gnome applet check
135 gnometrapplet_msg=No
136 AC_ARG_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)])
137 if test "$enable_gnomeapplet" = yes; then
138         experimental=yes
139         gnometrapplet_msg=Yes
140         clients="$clients gnome-trans-applet"
141 fi
142
143 # Gaim plugin check
144 gaimplugin_msg=No
145 AC_ARG_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable GNOME transfer applet (experimental)])
146 if test "$enable_gaimplugin" = yes; then
147         experimental=yes
148         gaimplugin_msg=Yes
149         clients="$clients gaim"
150 fi
151
152 # Guile check (XXX: Shouldn't have to be enabled manually)
153 guile_msg=No
154 if test "$with_guile" = yes; then
155         GUILE_FLAGS
156         extlibs="$extlibs guile"
157         guile_msg=Yes
158 fi
159
160 # Check whether to install baseconv
161 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
162 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
163
164 # Kerberos check
165 krb_msg=No
166 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSS-API) authentication])
167 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
168 if test "$with_krb5" != no; then
169         cpp_bak="$CPPFLAGS"
170         ld_bak="$LDFLAGS"
171         if test "$with_krb5" != yes; then
172                 CPPFLAGS="$CPPFLAGS -I${with_krb5}/include"
173                 LDFLAGS="$LDFLAGS -L${with_krb5}/lib"
174         fi
175         AC_CHECK_LIB(krb5, krb5_init_context, [HAS_KRB5=yes], [HAS_KRB5=no])
176         if test "$HAS_KRB5" = yes; then
177                 AC_CHECK_HEADER(com_err.h, [HAS_COMERR=yes], [HAS_COMERR=no])
178                 if test "$HAS_COMERR" = no; then
179                         AC_CHECK_HEADER(et/com_err.h, [HAS_COMERR=yes; CPPFLAGS="$CPPFLAGS -I/usr/include/et"], [])
180                 fi
181         fi
182         if test "$HAS_COMERR" = no; then
183                 HAS_KRB5=no
184         fi
185         if test "$HAS_KRB5" = no; then
186                 CPPFLAGS="$cpp_bak"
187                 LDFLAGS="$ld_bak"
188         fi
189 fi
190 KRB5_LDADD=
191 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" != yes; then
192         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system - try passing --with-krb5=/path/to/kerberos])
193 fi
194 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
195         AC_DEFINE(HAVE_KRB5)
196         KRB5_LDADD=-lkrb5
197         krb_msg=Yes
198 fi
199 AC_SUBST([KRB5_LDADD])
200
201 # Misc. functions checks
202 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
203 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
204 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
205
206 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
207 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
208
209 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
210 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
211
212 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
213 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
214                                   LDFLAGS="$LDFLAGS -lresolv" ])
215 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
216 AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS)
217                                         LDFLAGS="$LDFLAGS -lkeyutils" ])
218
219 # Unix credentials selector
220 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
221 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
222 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
223 AC_MSG_CHECKING([for Unix auth style])
224 if test $linuxcreds = y; then
225         AC_DEFINE(UNIX_AUTH_STYLE, 1)
226         AC_MSG_RESULT(linux)
227 elif test $bsdcreds = y; then
228         AC_DEFINE(UNIX_AUTH_STYLE, 2)
229         AC_MSG_RESULT(bsd)
230 else
231         AC_MSG_RESULT(none)
232 fi
233
234 AC_HEADER_STDC
235 AC_HEADER_DIRENT
236 AC_HEADER_SYS_WAIT
237
238 AC_TYPE_PID_T
239 AC_TYPE_SIZE_T
240 AC_HEADER_TIME
241 AC_TYPE_SIGNAL
242
243 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
244
245 AC_SUBST([clients extlibs])
246 AC_OUTPUT([
247 Makefile
248 autopackage/Makefile
249 common/Makefile
250 daemon/Makefile
251 lib/Makefile
252 lib/guile/Makefile
253 lib/guile/dolcon/Makefile
254 clients/Makefile
255 clients/gtk2/Makefile
256 clients/tty/Makefile
257 clients/gnome-trans-applet/Makefile
258 clients/gaim/Makefile
259 include/Makefile
260 include/doldaconnect/Makefile
261 doc/Makefile
262 doc/man/Makefile
263 po/Makefile.in
264 config/Makefile
265 contrib/Makefile
266 autopackage/dolcon.apspec
267 autopackage/dcuilib.apspec
268 autopackage/dcguile.apspec
269 ])
270
271 echo
272 echo "Dolda Connect has been configured with the following settings:"
273 echo
274 echo "    Kerberos 5 support:      $krb_msg"
275 echo "    GTK2 user interface:     $gtk2ui_msg"
276 echo "    GTK2 progress bars:      $gtk2pbar_msg"
277 echo "    Dolconf configurator:    $dolconf_msg"
278 echo "    Guile extension library: $guile_msg"
279 echo "    GNOME transfer applet:   $gnometrapplet_msg"
280 echo "    Gaim chat plugin:        $gaimplugin_msg"
281 echo
282
283 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
284         hastput=y
285 fi
286 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
287         if test "$hastput" = y; then
288                 tput bold
289                 tput setf 4 2>/dev/null
290         fi
291         echo -n "    Warning: " >&2
292         if test "$hastput" = y; then
293                 tput sgr0
294         fi
295         echo "Could not find a GTK2 development installation on this system." >&2
296         echo "             That means you won't get a UI." >&2
297         echo "             Make absolutely sure this is what you want!" >&2
298         if test "$hastput" = y; then
299                 tput bel
300         fi
301         sleep 1
302 fi
303 if test "$experimental" = yes; then
304         if test "$hastput" = y; then
305                 tput bold
306                 tput setf 4 2>/dev/null
307         fi
308         echo -n "    Warning: " >&2
309         if test "$hastput" = y; then
310                 tput sgr0
311         fi
312         echo "You have enabled one or more experimental features!" >&2
313         echo "             Please don't complain that it doesn't work, unless" >&2
314         echo "             you have something constructive to add about the situation." >&2
315         if test "$hastput" = y; then
316                 tput bel
317         fi
318         sleep 1
319 fi