configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.5])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 DOLDA_AC_GROUP([Checking required libraries])
  25
  26 AC_CHECK_LIB(z, deflate, [:], AC_MSG_ERROR([*** must have zlib]))
  27 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, [:], AC_MSG_ERROR([*** must have bzlib]))
  28 AC_CHECK_LIB(gdbm, gdbm_open, [:], AC_MSG_ERROR([*** must have gdbm]))
  29
  30 extlibs=
  31 experimental=no
  32
  33 DOLDA_AC_GROUP([Checking optional libraries])
  34
  35 # PAM check
  36 pam_msg=no
  37 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  38 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  39 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  40                      [AC_CHECK_LIB(pam, pam_start, [:], [HAS_PAM=no])],
  41                      [PAM_LIBS=-lpam])
  42 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  43         AC_MSG_ERROR([*** cannot find PAM on this system])
  44 fi
  45 if test "$HAS_PAM" = yes; then
  46         AC_DEFINE(HAVE_PAM)
  47         pam_msg=yes
  48 fi
  49 AC_SUBST(PAM_LIBS)
  50
  51 # Gtk 2.0 check
  52 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  53 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  54                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  55                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  56                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  57 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  58         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  59 fi
  60
  61 # libxml2 check
  62 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  63 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  64                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  65                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  66                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  67 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  68         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  69 fi
  70
  71 # libnotify check
  72 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  73 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  74 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  75                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  76                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  77 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  78         AC_MSG_ERROR([*** cannot find libnotify on this system])
  79 fi
  80 if test "$HAS_LIBNOTIFY" = yes; then
  81         AC_DEFINE(HAVE_NOTIFY)
  82 fi
  83
  84 # libpanelapplet check
  85 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  86
  87 # Gaim/Pidgin check
  88 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  89                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  90 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  91                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  92
  93 # Daemon check
  94 DOLDA_ENABLE(daemon, [  --enable-daemon         Enable the daemon], yes, [])
  95 AM_CONDITIONAL(DAEMON, test "$enable_daemon" = yes)
  96
  97 # Gtk GUI check
  98 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
  99                      [HAS_GTK2 HAS_LIBXML])
 100 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
 101
 102 # Dolconf check
 103 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
 104                       [HAS_GTK2])
 105 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 106
 107 # GUI shell check
 108 DOLDA_ENABLE(guishell, [  --enable-guishell       Build the GUI shell programs], yes,
 109                        [HAS_GTK2])
 110 AM_CONDITIONAL(GUISHELL, test "$enable_guishell" = yes)
 111
 112 # Gtk progress bar check
 113 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
 114 DOLDA_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)], no,
 115                        [HAS_GTK2 enable_gtk2ui])
 116 if test "$enable_gtk2pbar" = yes; then
 117         experimental=yes
 118         AC_DEFINE(ENABLE_GTK2PBAR)
 119 fi
 120
 121 # Gnome applet check
 122 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
 123                           [HAS_LIBPANELAPPLET])
 124 if test "$enable_gnomeapplet" = yes; then
 125         experimental=yes
 126 fi
 127 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 128
 129 # Gaim plugin check
 130 gaimplugin_msg=
 131 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 132                          [HAS_LIBGAIM])
 133 if test "$enable_gaimplugin" = yes; then
 134         experimental=yes
 135         gaimplugin_msg="Gaim $gaimplugin_msg"
 136 fi
 137 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 138 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 139                            [HAS_LIBPURPLE])
 140 if test "$enable_pidginplugin" = yes; then
 141         experimental=yes
 142         gaimplugin_msg="Pidgin $gaimplugin_msg"
 143 fi
 144 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 145 if test -z "$gaimplugin_msg"; then
 146         gaimplugin_msg=none
 147 fi
 148
 149 # Guile check (XXX: Shouldn't have to be enabled manually)
 150 guile_msg=no
 151 if test "$with_guile" = yes; then
 152         GUILE_FLAGS
 153         extlibs="$extlibs guile"
 154         guile_msg=yes
 155 fi
 156
 157 # Check whether to install baseconv
 158 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 159 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 160
 161 # Kerberos check
 162 krb_msg=no
 163 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 164 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 165 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 166 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 167                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 168                         [HAS_COMERR=no])
 169 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 170                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 171                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 172                       [KRB5_LIBS="`krb5-config --libs krb5`"
 173                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 174                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 175                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 176 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 177         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 178 fi
 179 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 180         AC_DEFINE(HAVE_KRB5)
 181         krb_msg=yes
 182 fi
 183 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 184
 185 # Linux keyring
 186 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 187 AC_ARG_WITH(keyutils, [  --with-keyutils           Enable support for the Linux keyring stash])
 188 DOLDA_PKG([HAS_KEYUTILS], [test "$with_keyutils" = no && HAS_KEYUTILS=no],
 189                           [AC_CHECK_LIB(keyutils, keyctl_search, [:], [HAS_KEYUTILS=no])])
 190 if test "$with_keyutils" = yes -a "$HAS_KEYUTILS" = no; then
 191         AC_MSG_ERROR([*** cannot find keyutils on this system])
 192 fi
 193 if test "$HAS_KEYUTILS" = yes; then
 194         AC_DEFINE(HAVE_KEYUTILS)
 195         KEYUTILS_LIBS=-lkeyutils
 196 fi
 197 AC_SUBST([KEYUTILS_LIBS])
 198
 199 DOLDA_AC_GROUP([Checking operating system features])
 200
 201 # Misc. functions checks
 202 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 203 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 204 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 205
 206 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 207 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 208
 209 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 210 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 211
 212 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 213 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 214                                   LDFLAGS="$LDFLAGS -lresolv" ])
 215
 216 # Unix credentials selector
 217 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 218 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 219 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 220 AC_MSG_CHECKING([for Unix auth style])
 221 if test $linuxcreds = y; then
 222         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 223         AC_MSG_RESULT(linux)
 224 elif test $bsdcreds = y; then
 225         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 226         AC_MSG_RESULT(bsd)
 227 else
 228         AC_MSG_RESULT(none)
 229 fi
 230
 231 DOLDA_AC_GROUP([Checking standard headers])
 232
 233 AC_HEADER_STDC
 234 AC_HEADER_DIRENT
 235 AC_HEADER_SYS_WAIT
 236
 237 AC_TYPE_PID_T
 238 AC_TYPE_SIZE_T
 239 AC_HEADER_TIME
 240 AC_TYPE_SIGNAL
 241
 242 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 243
 244 DOLDA_AC_GROUP([Writing output])
 245
 246 AC_SUBST([extlibs])
 247 AC_OUTPUT([
 248 Makefile
 249 autopackage/Makefile
 250 common/Makefile
 251 daemon/Makefile
 252 lib/Makefile
 253 lib/guile/Makefile
 254 lib/guile/dolcon/Makefile
 255 clients/Makefile
 256 clients/gtk2/Makefile
 257 clients/tty/Makefile
 258 clients/gnome-trans-applet/Makefile
 259 clients/gaim/Makefile
 260 clients/gui-shell/Makefile
 261 include/Makefile
 262 include/doldaconnect/Makefile
 263 doc/Makefile
 264 doc/man/Makefile
 265 po/Makefile.in
 266 config/Makefile
 267 config/cmd/Makefile
 268 config/util/Makefile
 269 contrib/Makefile
 270 autopackage/dolcon.apspec
 271 autopackage/dcuilib.apspec
 272 autopackage/dcguile.apspec
 273 ])
 274
 275 echo
 276 echo "Dolda Connect has been configured with the following settings:"
 277 echo
 278 echo "    Daemon:                  $enable_daemon"
 279 echo "    PAM support:             $pam_msg"
 280 echo "    Kerberos 5 support:      $krb_msg"
 281 echo "    GTK2 user interface:     $enable_gtk2ui"
 282 echo "    GTK2 progress bars:      $enable_gtk2pbar"
 283 echo "    Dolconf configurator:    $enable_dolconf"
 284 echo "    GUI shell:               $enable_guishell"
 285 echo "    Guile extension library: $guile_msg"
 286 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 287 echo "    Gaim chat plugin:        $gaimplugin_msg"
 288 echo
 289
 290 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 291         hastput=y
 292 fi
 293 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 294         if test "$hastput" = y; then
 295                 tput bold
 296                 tput setf 4 2>/dev/null
 297         fi
 298         echo -n "    Warning: " >&2
 299         if test "$hastput" = y; then
 300                 tput sgr0
 301         fi
 302         echo "Could not find a GTK2 development installation on this system." >&2
 303         echo "             That means you won't get a UI." >&2
 304         echo "             Make absolutely sure this is what you want!" >&2
 305         if test "$hastput" = y; then
 306                 tput bel
 307         fi
 308         sleep 1
 309 fi
 310 if test "$experimental" = yes; then
 311         if test "$hastput" = y; then
 312                 tput bold
 313                 tput setf 4 2>/dev/null
 314         fi
 315         echo -n "    Warning: " >&2
 316         if test "$hastput" = y; then
 317                 tput sgr0
 318         fi
 319         echo "You have enabled one or more experimental features!" >&2
 320         echo "             Please don't complain that it doesn't work, unless" >&2
 321         echo "             you have something constructive to add about the situation." >&2
 322         if test "$hastput" = y; then
 323                 tput bel
 324         fi
 325         sleep 1
 326 fi