configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.5])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 DOLDA_AC_GROUP([Checking required libraries])
  25
  26 AC_CHECK_LIB(pam, pam_start, , AC_MSG_ERROR([*** must have PAM]))
  27 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
  28 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
  29 AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm]))
  30
  31 extlibs=
  32 experimental=no
  33
  34 DOLDA_AC_GROUP([Checking optional libraries])
  35
  36 # Gtk 2.0 check
  37 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  38 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  39                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  40                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  41                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  42 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  43         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  44 fi
  45
  46 # libxml2 check
  47 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  48 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  49                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  50                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  51                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  52 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  53         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  54 fi
  55
  56 # libnotify check
  57 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  58 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  59                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  60                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  61 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  62         AC_MSG_ERROR([*** cannot find libnotify on this system])
  63 fi
  64
  65 # libpanelapplet check
  66 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  67
  68 # Gaim/Pidgin check
  69 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  70                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  71 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  72                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  73
  74 # Gtk GUI check
  75 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
  76                      [HAS_GTK2 HAS_LIBXML])
  77 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
  78
  79 # Dolconf check
  80 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
  81                       [HAS_GTK2])
  82 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
  83
  84 # Gtk progress bar check
  85 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
  86 DOLDA_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)], no,
  87                        [HAS_GTK2 enable_gtk2ui])
  88 if test "$enable_gtk2pbar" = yes; then
  89         experimental=yes
  90         AC_DEFINE(ENABLE_GTK2PBAR)
  91 fi
  92
  93 # Gnome applet check
  94 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
  95                           [HAS_LIBPANELAPPLET])
  96 if test "$enable_gnomeapplet" = yes; then
  97         experimental=yes
  98 fi
  99 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 100
 101 # Gaim plugin check
 102 gaimplugin_msg=
 103 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 104                          [HAS_LIBGAIM])
 105 if test "$enable_gaimplugin" = yes; then
 106         experimental=yes
 107         gaimplugin_msg="Gaim $gaimplugin_msg"
 108 fi
 109 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 110 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 111                            [HAS_LIBPURPLE])
 112 if test "$enable_pidginplugin" = yes; then
 113         experimental=yes
 114         gaimplugin_msg="Pidgin $gaimplugin_msg"
 115 fi
 116 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 117 if test -z "$gaimplugin_msg"; then
 118         gaimplugin_msg=none
 119 fi
 120
 121 # Guile check (XXX: Shouldn't have to be enabled manually)
 122 guile_msg=no
 123 if test "$with_guile" = yes; then
 124         GUILE_FLAGS
 125         extlibs="$extlibs guile"
 126         guile_msg=yes
 127 fi
 128
 129 # Check whether to install baseconv
 130 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 131 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 132
 133 # Kerberos check
 134 krb_msg=no
 135 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 136 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 137 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 138 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 139                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 140                         [HAS_COMERR=no])
 141 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 142                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 143                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 144                       [KRB5_LIBS="`krb5-config --libs krb5`"
 145                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 146                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 147                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 148 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 149         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 150 fi
 151 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 152         AC_DEFINE(HAVE_KRB5)
 153         krb_msg=yes
 154 fi
 155 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 156
 157 DOLDA_AC_GROUP([Checking operating system features])
 158
 159 # Misc. functions checks
 160 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 161 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 162 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 163
 164 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 165 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 166
 167 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 168 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 169
 170 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 171 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 172                                   LDFLAGS="$LDFLAGS -lresolv" ])
 173 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 174 AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS)
 175                                         LDFLAGS="$LDFLAGS -lkeyutils" ])
 176
 177 # Unix credentials selector
 178 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 179 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 180 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 181 AC_MSG_CHECKING([for Unix auth style])
 182 if test $linuxcreds = y; then
 183         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 184         AC_MSG_RESULT(linux)
 185 elif test $bsdcreds = y; then
 186         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 187         AC_MSG_RESULT(bsd)
 188 else
 189         AC_MSG_RESULT(none)
 190 fi
 191
 192 DOLDA_AC_GROUP([Checking standard headers])
 193
 194 AC_HEADER_STDC
 195 AC_HEADER_DIRENT
 196 AC_HEADER_SYS_WAIT
 197
 198 AC_TYPE_PID_T
 199 AC_TYPE_SIZE_T
 200 AC_HEADER_TIME
 201 AC_TYPE_SIGNAL
 202
 203 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 204
 205 DOLDA_AC_GROUP([Writing output])
 206
 207 AC_SUBST([extlibs])
 208 AC_OUTPUT([
 209 Makefile
 210 autopackage/Makefile
 211 common/Makefile
 212 daemon/Makefile
 213 lib/Makefile
 214 lib/guile/Makefile
 215 lib/guile/dolcon/Makefile
 216 clients/Makefile
 217 clients/gtk2/Makefile
 218 clients/tty/Makefile
 219 clients/gnome-trans-applet/Makefile
 220 clients/gaim/Makefile
 221 include/Makefile
 222 include/doldaconnect/Makefile
 223 doc/Makefile
 224 doc/man/Makefile
 225 po/Makefile.in
 226 config/Makefile
 227 config/cmd/Makefile
 228 config/util/Makefile
 229 contrib/Makefile
 230 autopackage/dolcon.apspec
 231 autopackage/dcuilib.apspec
 232 autopackage/dcguile.apspec
 233 ])
 234
 235 echo
 236 echo "Dolda Connect has been configured with the following settings:"
 237 echo
 238 echo "    Kerberos 5 support:      $krb_msg"
 239 echo "    GTK2 user interface:     $enable_gtk2ui"
 240 echo "    GTK2 progress bars:      $enable_gtk2pbar"
 241 echo "    Dolconf configurator:    $enable_dolconf"
 242 echo "    Guile extension library: $guile_msg"
 243 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 244 echo "    Gaim chat plugin:        $gaimplugin_msg"
 245 echo
 246
 247 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 248         hastput=y
 249 fi
 250 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 251         if test "$hastput" = y; then
 252                 tput bold
 253                 tput setf 4 2>/dev/null
 254         fi
 255         echo -n "    Warning: " >&2
 256         if test "$hastput" = y; then
 257                 tput sgr0
 258         fi
 259         echo "Could not find a GTK2 development installation on this system." >&2
 260         echo "             That means you won't get a UI." >&2
 261         echo "             Make absolutely sure this is what you want!" >&2
 262         if test "$hastput" = y; then
 263                 tput bel
 264         fi
 265         sleep 1
 266 fi
 267 if test "$experimental" = yes; then
 268         if test "$hastput" = y; then
 269                 tput bold
 270                 tput setf 4 2>/dev/null
 271         fi
 272         echo -n "    Warning: " >&2
 273         if test "$hastput" = y; then
 274                 tput sgr0
 275         fi
 276         echo "You have enabled one or more experimental features!" >&2
 277         echo "             Please don't complain that it doesn't work, unless" >&2
 278         echo "             you have something constructive to add about the situation." >&2
 279         if test "$hastput" = y; then
 280                 tput bel
 281         fi
 282         sleep 1
 283 fi