configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.1])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7
   8 AM_GNU_GETTEXT_VERSION(0.12.1)
   9 AM_GNU_GETTEXT([external])
  10 AM_PROG_LIBTOOL
  11
  12 AC_CHECK_LIB(pam, pam_start, , AC_MSG_ERROR([*** must have PAM]))
  13 AC_CHECK_LIB(dl, dlopen, , AC_MSG_ERROR([*** PAM requires a working dynamic loader (libdl)]))
  14 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
  15 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
  16
  17 clients=
  18 extlibs=
  19 experimental=no
  20
  21 AC_CHECK_PROG([PKG_CONFIG], pkg-config, yes, no)
  22
  23 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  24 if test "$with_gtk2" = no; then
  25         HAS_GTK2=no
  26 fi
  27 if test "$HAS_GTK2" != no; then
  28         if test "$PKG_CONFIG" = yes; then
  29                 AC_MSG_CHECKING([for GTK2 package information])
  30                 if pkg-config --modversion gtk+-2.0 >/dev/null 2>&1; then
  31                         AC_MSG_RESULT(yes)
  32                 else
  33                         AC_MSG_RESULT(no)
  34                         HAS_GTK2=no
  35                 fi
  36                 if test "$HAS_GTK2" != no; then
  37                         AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [HAS_GTK2=yes], [HAS_GTK2=no], `pkg-config --libs gtk+-2.0`)
  38                 fi
  39                 if test "$HAS_GTK2" = yes; then
  40                         cpp_bak="$CPPFLAGS"
  41                         CPPFLAGS="$CPPFLAGS `pkg-config --cflags gtk+-2.0`"
  42                         AC_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no])
  43                         CPPFLAGS="$cpp_bak"
  44                 fi
  45         else
  46                 HAS_GTK2=no
  47         fi
  48 fi
  49 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  50         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  51 fi
  52
  53 gtk2ui_msg=No
  54 AC_ARG_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface])
  55 if test "$enable_gtk2ui" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot build the GTK2 UI without a GTK2 library])
  57 fi
  58 if test "$enable_gtk2ui" != no -a "$HAS_GTK2" = yes; then
  59         clients="$clients gtk2"
  60         gtk2ui_msg=Yes
  61 fi
  62
  63 gtk2pbar_msg=No
  64 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
  65 AC_ARG_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)])
  66 if test "$enable_gtk2pbar" = yes; then
  67         if test "$HAS_GTK2" = no; then
  68                 AC_MSG_ERROR([*** cannot build GTK2 progress bars without GTK2])
  69         fi
  70         experimental=yes
  71         gtk2pbar_msg=Yes
  72         AC_DEFINE(ENABLE_GTK2PBAR)
  73 fi
  74
  75 gnometrapplet_msg=No
  76 AC_ARG_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)])
  77 if test "$enable_gnomeapplet" = yes; then
  78         experimental=yes
  79         gnometrapplet_msg=Yes
  80         clients="$clients gnome-trans-applet"
  81 fi
  82
  83 guile_msg=No
  84 if test "$with_guile" = yes; then
  85         GUILE_FLAGS
  86         extlibs="$extlibs guile"
  87         guile_msg=Yes
  88 fi
  89
  90 krb_msg=No
  91 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSS-API) authentication])
  92 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
  93 if test "$with_krb5" != no; then
  94         cpp_bak="$CPPFLAGS"
  95         ld_bak="$LDFLAGS"
  96         if test "$with_krb5" != yes; then
  97                 CPPFLAGS="$CPPFLAGS -I${with_krb5}/include"
  98                 LDFLAGS="$LDFLAGS -L${with_krb5}/lib"
  99         fi
 100         AC_CHECK_LIB(krb5, krb5_init_context, [HAS_KRB5=yes], [HAS_KRB5=no])
 101         if test "$HAS_KRB5" = yes; then
 102                 AC_CHECK_HEADER(com_err.h, [HAS_COMERR=yes], [HAS_COMERR=no])
 103                 if test "$HAS_COMERR" = no; then
 104                         AC_CHECK_HEADER(et/com_err.h, [HAS_COMERR=yes; CPPFLAGS="$CPPFLAGS -I/usr/include/et"], [])
 105                 fi
 106         fi
 107         if test "$HAS_COMERR" = no; then
 108                 HAS_KRB5=no
 109         fi
 110         if test "$HAS_KRB5" = no; then
 111                 CPPFLAGS="$cpp_bak"
 112                 LDFLAGS="$ld_bak"
 113         fi
 114 fi
 115 KRB5_LDADD=
 116 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" != yes; then
 117         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system - try passing --with-krb5=/path/to/kerberos])
 118 fi
 119 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 120         AC_DEFINE(HAVE_KRB5)
 121         KRB5_LDADD=-lkrb5
 122         krb_msg=Yes
 123 fi
 124 AC_SUBST([KRB5_LDADD])
 125
 126 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 127 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 128 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 129
 130 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 131 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 132
 133 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 134 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 135
 136 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 137 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 138                                   LDFLAGS="$LDFLAGS -lresolv" ])
 139
 140 AC_HEADER_STDC
 141 AC_HEADER_DIRENT
 142 AC_HEADER_SYS_WAIT
 143
 144 AC_TYPE_PID_T
 145 AC_TYPE_SIZE_T
 146 AC_HEADER_TIME
 147 AC_TYPE_SIGNAL
 148
 149 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 150
 151 AC_SUBST([clients extlibs])
 152 AC_OUTPUT([
 153 Makefile
 154 daemon/Makefile
 155 lib/Makefile
 156 lib/guile/Makefile
 157 lib/guile/dolcon/Makefile
 158 clients/Makefile
 159 clients/gtk2/Makefile
 160 clients/gnome-trans-applet/Makefile
 161 include/Makefile
 162 po/Makefile.in
 163 config/Makefile
 164 autopackage/dolcon.apspec
 165 ])
 166
 167 echo
 168 echo "Dolda Connect has been configured with the following settings:"
 169 echo
 170 echo "    Kerberos 5 support:      $krb_msg"
 171 echo "    GTK2 user interface:     $gtk2ui_msg"
 172 echo "    GTK2 progress bars:      $gtk2pbar_msg"
 173 echo "    Guile extension library: $guile_msg"
 174 echo "    GNOME transfer applet:   $gnometrapplet_msg"
 175 echo
 176
 177 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 178         hastput=y
 179 fi
 180 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 181         if test "$hastput" = y; then
 182                 tput bold
 183                 tput setf 4 2>/dev/null
 184         fi
 185         echo -n "    Warning: " >&2
 186         if test "$hastput" = y; then
 187                 tput sgr0
 188         fi
 189         echo "Could not find a GTK2 development installation on this system." >&2
 190         echo "             That means you won't get a UI." >&2
 191         echo "             Make absolutely sure this is what you want!" >&2
 192         if test "$hastput" = y; then
 193                 tput bel
 194         fi
 195         sleep 1
 196 fi
 197 if test "$experimental" = yes; then
 198         if test "$hastput" = y; then
 199                 tput bold
 200                 tput setf 4 2>/dev/null
 201         fi
 202         echo -n "    Warning: " >&2
 203         if test "$hastput" = y; then
 204                 tput sgr0
 205         fi
 206         echo "You have enabled one or more experimental features!" >&2
 207         echo "             Please don't complain that it doesn't work, unless" >&2
 208         echo "             you have something constructive to add about the situation." >&2
 209         if test "$hastput" = y; then
 210                 tput bel
 211         fi
 212         sleep 1
 213 fi