configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.5])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 DOLDA_AC_GROUP([Checking required libraries])
  25
  26 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
  27 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
  28 AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm]))
  29
  30 extlibs=
  31 experimental=no
  32
  33 DOLDA_AC_GROUP([Checking optional libraries])
  34
  35 # PAM check
  36 pam_msg=no
  37 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  38 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  39 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  40                      [AC_CHECK_LIB(pam, pam_start, , [HAS_PAM=no])])
  41 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  42         AC_MSG_ERROR([*** cannot find PAM on this system])
  43 fi
  44 if test "$HAS_PAM" = yes; then
  45         AC_DEFINE(HAVE_PAM)
  46         pam_msg=yes
  47 fi
  48
  49 # Gtk 2.0 check
  50 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  51 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  52                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  53                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  54                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  55 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  57 fi
  58
  59 # libxml2 check
  60 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  61 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  62                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  63                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  64                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  65 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  66         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  67 fi
  68
  69 # libnotify check
  70 AH_TEMPLATE(HAVE_NOTIFY, [define to compile support for libnotify])
  71 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  72 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  73                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  74                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  75 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  76         AC_MSG_ERROR([*** cannot find libnotify on this system])
  77 fi
  78 if test "$HAS_LIBNOTIFY" = yes; then
  79         AC_DEFINE(HAVE_NOTIFY)
  80 fi
  81
  82 # libpanelapplet check
  83 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  84
  85 # Gaim/Pidgin check
  86 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  87                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  88 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  89                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  90
  91 # Gtk GUI check
  92 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
  93                      [HAS_GTK2 HAS_LIBXML])
  94 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
  95
  96 # Dolconf check
  97 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
  98                       [HAS_GTK2])
  99 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
 100
 101 # Gtk progress bar check
 102 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
 103 DOLDA_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)], no,
 104                        [HAS_GTK2 enable_gtk2ui])
 105 if test "$enable_gtk2pbar" = yes; then
 106         experimental=yes
 107         AC_DEFINE(ENABLE_GTK2PBAR)
 108 fi
 109
 110 # Gnome applet check
 111 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
 112                           [HAS_LIBPANELAPPLET])
 113 if test "$enable_gnomeapplet" = yes; then
 114         experimental=yes
 115 fi
 116 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 117
 118 # Gaim plugin check
 119 gaimplugin_msg=
 120 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 121                          [HAS_LIBGAIM])
 122 if test "$enable_gaimplugin" = yes; then
 123         experimental=yes
 124         gaimplugin_msg="Gaim $gaimplugin_msg"
 125 fi
 126 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 127 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 128                            [HAS_LIBPURPLE])
 129 if test "$enable_pidginplugin" = yes; then
 130         experimental=yes
 131         gaimplugin_msg="Pidgin $gaimplugin_msg"
 132 fi
 133 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 134 if test -z "$gaimplugin_msg"; then
 135         gaimplugin_msg=none
 136 fi
 137
 138 # Guile check (XXX: Shouldn't have to be enabled manually)
 139 guile_msg=no
 140 if test "$with_guile" = yes; then
 141         GUILE_FLAGS
 142         extlibs="$extlibs guile"
 143         guile_msg=yes
 144 fi
 145
 146 # Check whether to install baseconv
 147 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 148 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 149
 150 # Kerberos check
 151 krb_msg=no
 152 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 153 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 154 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 155 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 156                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 157                         [HAS_COMERR=no])
 158 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 159                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 160                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 161                       [KRB5_LIBS="`krb5-config --libs krb5`"
 162                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 163                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 164                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 165 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 166         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 167 fi
 168 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 169         AC_DEFINE(HAVE_KRB5)
 170         krb_msg=yes
 171 fi
 172 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 173
 174 DOLDA_AC_GROUP([Checking operating system features])
 175
 176 # Misc. functions checks
 177 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 178 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 179 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 180
 181 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 182 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 183
 184 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 185 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 186
 187 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 188 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 189                                   LDFLAGS="$LDFLAGS -lresolv" ])
 190 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 191 AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS)
 192                                         LDFLAGS="$LDFLAGS -lkeyutils" ])
 193
 194 # Unix credentials selector
 195 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 196 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 197 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 198 AC_MSG_CHECKING([for Unix auth style])
 199 if test $linuxcreds = y; then
 200         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 201         AC_MSG_RESULT(linux)
 202 elif test $bsdcreds = y; then
 203         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 204         AC_MSG_RESULT(bsd)
 205 else
 206         AC_MSG_RESULT(none)
 207 fi
 208
 209 DOLDA_AC_GROUP([Checking standard headers])
 210
 211 AC_HEADER_STDC
 212 AC_HEADER_DIRENT
 213 AC_HEADER_SYS_WAIT
 214
 215 AC_TYPE_PID_T
 216 AC_TYPE_SIZE_T
 217 AC_HEADER_TIME
 218 AC_TYPE_SIGNAL
 219
 220 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 221
 222 DOLDA_AC_GROUP([Writing output])
 223
 224 AC_SUBST([extlibs])
 225 AC_OUTPUT([
 226 Makefile
 227 autopackage/Makefile
 228 common/Makefile
 229 daemon/Makefile
 230 lib/Makefile
 231 lib/guile/Makefile
 232 lib/guile/dolcon/Makefile
 233 clients/Makefile
 234 clients/gtk2/Makefile
 235 clients/tty/Makefile
 236 clients/gnome-trans-applet/Makefile
 237 clients/gaim/Makefile
 238 clients/gui-shell/Makefile
 239 include/Makefile
 240 include/doldaconnect/Makefile
 241 doc/Makefile
 242 doc/man/Makefile
 243 po/Makefile.in
 244 config/Makefile
 245 config/cmd/Makefile
 246 config/util/Makefile
 247 contrib/Makefile
 248 autopackage/dolcon.apspec
 249 autopackage/dcuilib.apspec
 250 autopackage/dcguile.apspec
 251 ])
 252
 253 echo
 254 echo "Dolda Connect has been configured with the following settings:"
 255 echo
 256 echo "    PAM support:             $pam_msg"
 257 echo "    Kerberos 5 support:      $krb_msg"
 258 echo "    GTK2 user interface:     $enable_gtk2ui"
 259 echo "    GTK2 progress bars:      $enable_gtk2pbar"
 260 echo "    Dolconf configurator:    $enable_dolconf"
 261 echo "    Guile extension library: $guile_msg"
 262 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 263 echo "    Gaim chat plugin:        $gaimplugin_msg"
 264 echo
 265
 266 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 267         hastput=y
 268 fi
 269 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 270         if test "$hastput" = y; then
 271                 tput bold
 272                 tput setf 4 2>/dev/null
 273         fi
 274         echo -n "    Warning: " >&2
 275         if test "$hastput" = y; then
 276                 tput sgr0
 277         fi
 278         echo "Could not find a GTK2 development installation on this system." >&2
 279         echo "             That means you won't get a UI." >&2
 280         echo "             Make absolutely sure this is what you want!" >&2
 281         if test "$hastput" = y; then
 282                 tput bel
 283         fi
 284         sleep 1
 285 fi
 286 if test "$experimental" = yes; then
 287         if test "$hastput" = y; then
 288                 tput bold
 289                 tput setf 4 2>/dev/null
 290         fi
 291         echo -n "    Warning: " >&2
 292         if test "$hastput" = y; then
 293                 tput sgr0
 294         fi
 295         echo "You have enabled one or more experimental features!" >&2
 296         echo "             Please don't complain that it doesn't work, unless" >&2
 297         echo "             you have something constructive to add about the situation." >&2
 298         if test "$hastput" = y; then
 299                 tput bel
 300         fi
 301         sleep 1
 302 fi