configure.in

   1 AC_INIT(daemon/main.c)
   2 AM_INIT_AUTOMAKE([doldaconnect], [0.5])
   3 AM_CONFIG_HEADER(config.h)
   4
   5 DOLDA_AC_GROUP([Checking build chain])
   6
   7 AC_PROG_CC
   8 AC_PROG_CC_C_O
   9 AM_PROG_CC_C_O
  10 AC_PROG_INSTALL
  11
  12 DOLDA_AC_GROUP([Configuring gettext])
  13
  14 AM_GNU_GETTEXT_VERSION(0.12.1)
  15 AM_GNU_GETTEXT([external])
  16
  17 DOLDA_AC_GROUP([Configuring libtool])
  18
  19 # Temporary hack to make libtool not check for g++ or g77
  20 m4_defun([_LT_AC_LANG_CXX_CONFIG], true)
  21 m4_defun([_LT_AC_LANG_F77_CONFIG], true)
  22 AC_PROG_LIBTOOL
  23
  24 DOLDA_AC_GROUP([Checking required libraries])
  25
  26 AC_CHECK_LIB(z, deflate, , AC_MSG_ERROR([*** must have zlib]))
  27 AC_CHECK_LIB(bz2, BZ2_bzWriteOpen, , AC_MSG_ERROR([*** must have bzlib]))
  28 AC_CHECK_LIB(gdbm, gdbm_open, , AC_MSG_ERROR([*** must have gdbm]))
  29
  30 extlibs=
  31 experimental=no
  32
  33 DOLDA_AC_GROUP([Checking optional libraries])
  34
  35 # PAM check
  36 pam_msg=no
  37 AH_TEMPLATE(HAVE_PAM, [define to compile support for PAM authentication])
  38 AC_ARG_WITH(pam, [  --with-pam              Enable PAM support])
  39 DOLDA_PKG([HAS_PAM], [test "$with_pam" = no && HAS_PAM=no],
  40                      [AC_CHECK_LIB(pam, pam_start, , [HAS_PAM=no])])
  41 if test "$with_pam" = yes -a "$HAS_PAM" = no; then
  42         AC_MSG_ERROR([*** cannot find PAM on this system])
  43 fi
  44 if test "$with_pam" != no -a "$HAS_PAM" = yes; then
  45         AC_DEFINE(HAVE_PAM)
  46         pam_msg=yes
  47 fi
  48
  49 # Gtk 2.0 check
  50 AC_ARG_WITH(gtk2, [  --with-gtk2             Enable GTK2 support])
  51 DOLDA_PKG([HAS_GTK2], [test "$with_gtk2" = no && HAS_GTK2=no],
  52                       [PKG_CHECK_MODULES(GTK2, gtk+-2.0, [], [HAS_GTK2=no])],
  53                       [AC_CHECK_LIB(gtk-x11-2.0, gtk_init, [:], [HAS_GTK2=no], $GTK2_LIBS)],
  54                       [DOLDA_CHECK_HEADER(gtk/gtk.h, [], [HAS_GTK2=no], $GTK2_CFLAGS)])
  55 if test "$with_gtk2" = yes -a "$HAS_GTK2" = no; then
  56         AC_MSG_ERROR([*** cannot find GTK2 on this system])
  57 fi
  58
  59 # libxml2 check
  60 AC_ARG_WITH(libxml2, [  --with-libxml2          Enable libxml2 support])
  61 DOLDA_PKG([HAS_LIBXML], [test "$with_libxml2" = no && HAS_LIBXML=no],
  62                         [PKG_CHECK_MODULES(LIBXML, libxml-2.0, [], [HAS_LIBXML=no])],
  63                         [AC_CHECK_LIB(xml2, xmlReadFile, [:], [HAS_LIBXML=no], $LIBXML_LIBS)],
  64                         [DOLDA_CHECK_HEADER(libxml/parser.h, [], [HAS_LIBXML=no], $LIBXML_CFLAGS)])
  65 if test "$with_libxml" = yes -a "$HAS_LIBXML" = no; then
  66         AC_MSG_ERROR([*** cannot find libxml2 on this system])
  67 fi
  68
  69 # libnotify check
  70 AC_ARG_WITH(libnotify, [  --with-libnotify        Enable libnotify support])
  71 DOLDA_PKG([HAS_LIBNOTIFY], [test "$with_libnotify" = no && HAS_LIBNOTIFY=no],
  72                            [PKG_CHECK_MODULES(LIBNOTIFY, libnotify, [], [HAS_LIBNOTIFY=no])],
  73                            [AC_CHECK_LIB(notify, notify_init, [:], [HAS_LIBNOTIFY=no], $LIBNOTIFY_LIBS)])
  74 if test "$with_libnotify" = yes -a "$HAS_LIBNOTIFY" = no; then
  75         AC_MSG_ERROR([*** cannot find libnotify on this system])
  76 fi
  77
  78 # libpanelapplet check
  79 DOLDA_PKG([HAS_LIBPANELAPPLET], [PKG_CHECK_MODULES(PANELAPPLET, libpanelapplet-2.0, [], [HAS_LIBPANELAPPLET=no])])
  80
  81 # Gaim/Pidgin check
  82 DOLDA_PKG([HAS_LIBGAIM], [PKG_CHECK_MODULES(GAIM, gaim, [], [HAS_LIBGAIM=no])],
  83                          [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBGAIM=no], $GAIM_CFLAGS)])
  84 DOLDA_PKG([HAS_LIBPURPLE], [PKG_CHECK_MODULES(PURPLE, purple, [], [HAS_LIBPURPLE=no])],
  85                            [DOLDA_CHECK_HEADER(plugin.h, [], [HAS_LIBPURPLE=no], $PURPLE_CFLAGS)])
  86
  87 # Gtk GUI check
  88 DOLDA_ENABLE(gtk2ui, [  --enable-gtk2ui         Enable the GTK2 user interface], yes,
  89                      [HAS_GTK2 HAS_LIBXML])
  90 AM_CONDITIONAL(CLI_GTK2, test "$enable_gtk2ui" = yes)
  91
  92 # Dolconf check
  93 DOLDA_ENABLE(dolconf, [  --enable-dolconf        Build the configuration helper], yes,
  94                       [HAS_GTK2])
  95 AM_CONDITIONAL(DOLCONF, test "$enable_dolconf" = yes)
  96
  97 # Gtk progress bar check
  98 AH_TEMPLATE(ENABLE_GTK2PBAR, [define to compile GTK2 progress bars (experimental)])
  99 DOLDA_ENABLE(gtk2pbar, [  --enable-gtk2pbar       Enable GTK2 progress bars (experimental)], no,
 100                        [HAS_GTK2 enable_gtk2ui])
 101 if test "$enable_gtk2pbar" = yes; then
 102         experimental=yes
 103         AC_DEFINE(ENABLE_GTK2PBAR)
 104 fi
 105
 106 # Gnome applet check
 107 DOLDA_ENABLE(gnomeapplet, [  --enable-gnomeapplet    Enable GNOME transfer applet (experimental)], no,
 108                           [HAS_LIBPANELAPPLET])
 109 if test "$enable_gnomeapplet" = yes; then
 110         experimental=yes
 111 fi
 112 AM_CONDITIONAL(CLI_GNOMEAPPLET, test "$enable_gnomeapplet" = yes)
 113
 114 # Gaim plugin check
 115 gaimplugin_msg=
 116 DOLDA_ENABLE(gaimplugin, [  --enable-gaimplugin     Enable Gaim chat plugin (experimental)], no,
 117                          [HAS_LIBGAIM])
 118 if test "$enable_gaimplugin" = yes; then
 119         experimental=yes
 120         gaimplugin_msg="Gaim $gaimplugin_msg"
 121 fi
 122 AM_CONDITIONAL(CLI_GAIM, test "$enable_gaimplugin" = yes)
 123 DOLDA_ENABLE(pidginplugin, [  --enable-pidginplugin   Enable Pidgin chat plugin (experimental)], no,
 124                            [HAS_LIBPURPLE])
 125 if test "$enable_pidginplugin" = yes; then
 126         experimental=yes
 127         gaimplugin_msg="Pidgin $gaimplugin_msg"
 128 fi
 129 AM_CONDITIONAL(CLI_PIDGIN, test "$enable_pidginplugin" = yes)
 130 if test -z "$gaimplugin_msg"; then
 131         gaimplugin_msg=none
 132 fi
 133
 134 # Guile check (XXX: Shouldn't have to be enabled manually)
 135 guile_msg=no
 136 if test "$with_guile" = yes; then
 137         GUILE_FLAGS
 138         extlibs="$extlibs guile"
 139         guile_msg=yes
 140 fi
 141
 142 # Check whether to install baseconv
 143 AC_ARG_ENABLE(baseconv, [  --enable-baseconv       Install the baseconv utility])
 144 AM_CONDITIONAL(BASECONV, test "$enable_baseconv" = yes)
 145
 146 # Kerberos check
 147 krb_msg=no
 148 AH_TEMPLATE(HAVE_KRB5, [define to compile support for Kerberos 5 (not GSSAPI) authentication])
 149 AC_ARG_WITH(krb5, [  --with-krb5[=PATH]        Enable Kerberos 5 (not GSSAPI) authentication])
 150 AC_CHECK_PROG(KRBCONF, krb5-config, yes, no)
 151 DOLDA_PKG([HAS_COMERR], [AC_CHECK_HEADER(com_err.h, [COMERR_CFLAGS=""; HAS_COMERR=yes], [])],
 152                         [AC_CHECK_HEADER(et/com_err.h, [COMERR_CFLAGS="-I/usr/include/et"; HAS_COMERR=yes], [])],
 153                         [HAS_COMERR=no])
 154 DOLDA_PKG([HAS_KRB5], [test "$with_krb5" = no && HAS_KRB5=no],
 155                       [test "$KRBCONF" != yes && HAS_KRB5=no],
 156                       [test "$HAS_COMERR" = no && HAS_KRB5=no],
 157                       [KRB5_LIBS="`krb5-config --libs krb5`"
 158                        KRB5_CFLAGS="`krb5-config --cflags krb5` $COMERR_CFLAGS"]
 159                       [AC_CHECK_LIB(krb5, krb5_init_context, [:], [HAS_KRB5=no], $KRB5_LIBS)],
 160                       [DOLDA_CHECK_HEADER(krb5.h, [], [HAS_KRB5=no], $KRB5_CFLAGS)])
 161 if test -n "$with_krb5" -a "$with_krb5" != no -a "$HAS_KRB5" = no; then
 162         AC_MSG_ERROR([*** cannot find Kerberos 5 on this system])
 163 fi
 164 if test "$with_krb5" != no -a "$HAS_KRB5" = yes; then
 165         AC_DEFINE(HAVE_KRB5)
 166         krb_msg=yes
 167 fi
 168 AC_SUBST([KRB5_LIBS KRB5_CFLAGS])
 169
 170 DOLDA_AC_GROUP([Checking operating system features])
 171
 172 # Misc. functions checks
 173 AC_CHECK_FUNC(vswprintf, , AC_MSG_ERROR([*** must have vswprintf]))
 174 AH_TEMPLATE(HAVE_WCSCASECMP, [define if your system implements wcscasecmp])
 175 AC_CHECK_FUNC(wcscasecmp, [ AC_DEFINE(HAVE_WCSCASECMP) ])
 176
 177 AH_TEMPLATE(HAVE_LINUX_SOCKIOS_H, [define if you have linux/sockios.h on your system])
 178 AC_CHECK_HEADER([linux/sockios.h], [ AC_DEFINE(HAVE_LINUX_SOCKIOS_H) ])
 179
 180 AH_TEMPLATE(HAVE_IPV6, [define if your system supports IPv6 and you wish to compile with support for it])
 181 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_family, [ AC_DEFINE(HAVE_IPV6) ], , [#include <netinet/in.h>])
 182
 183 AH_TEMPLATE(HAVE_RESOLVER, [define if your system supports the res_* functions to fetch DNS RRs])
 184 AC_CHECK_LIB(resolv, res_query, [ AC_DEFINE(HAVE_RESOLVER)
 185                                   LDFLAGS="$LDFLAGS -lresolv" ])
 186 AH_TEMPLATE(HAVE_KEYUTILS, [define if your system supports the Linux keyring functions])
 187 AC_CHECK_LIB(keyutils, keyctl_search, [ AC_DEFINE(HAVE_KEYUTILS)
 188                                         LDFLAGS="$LDFLAGS -lkeyutils" ])
 189
 190 # Unix credentials selector
 191 AH_TEMPLATE(UNIX_AUTH_STYLE, [undefine for no Unix auth, 1 for Linux style, 2 for BSD style])
 192 AC_CHECK_MEMBER(struct ucred.pid, [ linuxcreds=y ], [ linuxcreds=n ], [#include <sys/socket.h>])
 193 AC_CHECK_FUNC(getpeereid, [ bsdcreds=y ], [ bsdcreds=n ])
 194 AC_MSG_CHECKING([for Unix auth style])
 195 if test $linuxcreds = y; then
 196         AC_DEFINE(UNIX_AUTH_STYLE, 1)
 197         AC_MSG_RESULT(linux)
 198 elif test $bsdcreds = y; then
 199         AC_DEFINE(UNIX_AUTH_STYLE, 2)
 200         AC_MSG_RESULT(bsd)
 201 else
 202         AC_MSG_RESULT(none)
 203 fi
 204
 205 DOLDA_AC_GROUP([Checking standard headers])
 206
 207 AC_HEADER_STDC
 208 AC_HEADER_DIRENT
 209 AC_HEADER_SYS_WAIT
 210
 211 AC_TYPE_PID_T
 212 AC_TYPE_SIZE_T
 213 AC_HEADER_TIME
 214 AC_TYPE_SIGNAL
 215
 216 CPPFLAGS="-I\$(top_srcdir)/include $CPPFLAGS"
 217
 218 DOLDA_AC_GROUP([Writing output])
 219
 220 AC_SUBST([extlibs])
 221 AC_OUTPUT([
 222 Makefile
 223 autopackage/Makefile
 224 common/Makefile
 225 daemon/Makefile
 226 lib/Makefile
 227 lib/guile/Makefile
 228 lib/guile/dolcon/Makefile
 229 clients/Makefile
 230 clients/gtk2/Makefile
 231 clients/tty/Makefile
 232 clients/gnome-trans-applet/Makefile
 233 clients/gaim/Makefile
 234 clients/gui-shell/Makefile
 235 include/Makefile
 236 include/doldaconnect/Makefile
 237 doc/Makefile
 238 doc/man/Makefile
 239 po/Makefile.in
 240 config/Makefile
 241 config/cmd/Makefile
 242 config/util/Makefile
 243 contrib/Makefile
 244 autopackage/dolcon.apspec
 245 autopackage/dcuilib.apspec
 246 autopackage/dcguile.apspec
 247 ])
 248
 249 echo
 250 echo "Dolda Connect has been configured with the following settings:"
 251 echo
 252 echo "    PAM support:             $pam_msg"
 253 echo "    Kerberos 5 support:      $krb_msg"
 254 echo "    GTK2 user interface:     $enable_gtk2ui"
 255 echo "    GTK2 progress bars:      $enable_gtk2pbar"
 256 echo "    Dolconf configurator:    $enable_dolconf"
 257 echo "    Guile extension library: $guile_msg"
 258 echo "    GNOME transfer applet:   $enable_gnomeapplet"
 259 echo "    Gaim chat plugin:        $gaimplugin_msg"
 260 echo
 261
 262 if tput bold >/dev/null 2>&1 && tty <&2 >/dev/null 2>&1; then
 263         hastput=y
 264 fi
 265 if test "$HAS_GTK2" = no -a "$with_gtk2" != no -a "$enable_gtk2ui" != no; then
 266         if test "$hastput" = y; then
 267                 tput bold
 268                 tput setf 4 2>/dev/null
 269         fi
 270         echo -n "    Warning: " >&2
 271         if test "$hastput" = y; then
 272                 tput sgr0
 273         fi
 274         echo "Could not find a GTK2 development installation on this system." >&2
 275         echo "             That means you won't get a UI." >&2
 276         echo "             Make absolutely sure this is what you want!" >&2
 277         if test "$hastput" = y; then
 278                 tput bel
 279         fi
 280         sleep 1
 281 fi
 282 if test "$experimental" = yes; then
 283         if test "$hastput" = y; then
 284                 tput bold
 285                 tput setf 4 2>/dev/null
 286         fi
 287         echo -n "    Warning: " >&2
 288         if test "$hastput" = y; then
 289                 tput sgr0
 290         fi
 291         echo "You have enabled one or more experimental features!" >&2
 292         echo "             Please don't complain that it doesn't work, unless" >&2
 293         echo "             you have something constructive to add about the situation." >&2
 294         if test "$hastput" = y; then
 295                 tput bel
 296         fi
 297         sleep 1
 298 fi